1 files changed, 43 insertions, 0 deletions
diff --git a/dev-util/kdbg/kdbg-3.0.1.ebuild b/dev-util/kdbg/kdbg-3.0.1.ebuild
new file mode 100644
index 000000000000..5a91055027dd
--- /dev/null
+++ b/dev-util/kdbg/kdbg-3.0.1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="true"
+KFMIN=5.60.0
+QTMIN=5.12.3
+inherit ecm
+
+DESCRIPTION="Graphical debugger interface"
+HOMEPAGE="http://www.kdbg.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="5"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	sys-devel/gdb
+"
+
+src_prepare() {
+	# allow documentation to be handled by eclass
+	mv kdbg/doc . || die
+	sed -i -e '/add_subdirectory(doc)/d' kdbg/CMakeLists.txt || die
+	echo "add_subdirectory ( doc ) " >> CMakeLists.txt || die
+
+	ecm_src_prepare
+}