4 files changed, 51 insertions, 49 deletions
diff --git a/games-board/atakks/Manifest b/games-board/atakks/Manifest
index 20c02bb7b626..b8d92d3d58b3 100644
--- a/games-board/atakks/Manifest
+++ b/games-board/atakks/Manifest
@@ -1 +1,2 @@
 DIST atakks-1.0.tar.gz 62464 BLAKE2B 1419e4fff60121e0bd793322cd20515335ad82d9b1341ab9ae658aa5e2882af3457440485318b1d872f9f8f483c22b21d8dc55f5d4862694427d08fb52e93e85 SHA512 a4b31635ef74198c86002fc930922266f462926bffa5b1fd7fb8ba1186dbc1efd8ae8c84ac0a429737916d1350b5432967221a67505bfe73d47a6dadd7600e39
+DIST atakks.png 5084 BLAKE2B 52dcc313e7931fb0180f40803f3c276a0ee146a0e16af83f153d1d22800b0f780a2aa022cd198ad1ab70bb7ba252eeccfc1d34d6685b556a17ef1a96385fcd35 SHA512 c662fd1d0996317299a3085e7d5455c4eb24be22133cbaf9e720633c894bbd5ef69729b679326845c0702f8d7b72ba27b5825c3d1086b025520d11448f8706c4
diff --git a/games-board/atakks/atakks-1.0-r1.ebuild b/games-board/atakks/atakks-1.0-r1.ebuild
deleted file mode 100644
index 052924ba8c88..000000000000
--- a/games-board/atakks/atakks-1.0-r1.ebuild
+++ /dev/null
@@ -1,48 +0,0 @@
-# Copyright 1999-2016 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit eutils
-
-MY_P=${P/-/_}
-DESCRIPTION="A clone of Ataxx"
-HOMEPAGE="http://team.gcu-squad.org/~fab"
-# no version upstream
-#SRC_URI="http://team.gcu-squad.org/~fab/down/${PN}.tgz"
-SRC_URI="mirror://gentoo/${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE=""
-
-DEPEND="media-libs/libsdl:0"
-RDEPEND=${DEPEND}
-
-S=${WORKDIR}/${MY_P}
-
-PATCHES=(
-	"${FILESDIR}"/${PV}-warnings.patch
-	"${FILESDIR}"/${P}-as-needed.patch
-)
-
-src_prepare() {
-	default
-
-	# Modify game data paths
-	sed -i \
-		-e "s:SDL_LoadBMP(\":SDL_LoadBMP(\"/usr/share/${PN}/:" \
-		main.c || die
-}
-
-src_compile() {
-	emake E_CFLAGS="${CFLAGS}"
-}
-
-src_install() {
-	dobin ${PN}
-	insinto /usr/share/${PN}
-	doins *bmp
-	newicon icon.bmp ${PN}.bmp
-	make_desktop_entry ${PN} Atakks /usr/share/pixmaps/${PN}.bmp
-}
diff --git a/games-board/atakks/atakks-1.0-r2.ebuild b/games-board/atakks/atakks-1.0-r2.ebuild
new file mode 100644
index 000000000000..4dd2ccb10946
--- /dev/null
+++ b/games-board/atakks/atakks-1.0-r2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop toolchain-funcs
+
+DESCRIPTION="Clone of Ataxx"
+HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
+SRC_URI="
+	mirror://gentoo/${P}.tar.gz
+	https://dev.gentoo.org/~ionen/distfiles/${PN}.png"
+S="${WORKDIR}/${PN}_${PV}"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="media-libs/libsdl[video]"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PV}-warnings.patch
+	"${FILESDIR}"/${P}-as-needed.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i "/LoadBMP/s|\"|\"${EPREFIX}/usr/share/${PN}/|" main.c || die
+}
+
+src_compile() {
+	tc-export CC
+
+	emake E_CFLAGS="${CFLAGS}"
+}
+
+src_install() {
+	dobin ${PN}
+
+	insinto /usr/share/${PN}
+	doins *.bmp
+
+	einstalldocs
+
+	doicon "${DISTDIR}"/${PN}.png
+	make_desktop_entry ${PN} Atakks
+}
diff --git a/games-board/atakks/metadata.xml b/games-board/atakks/metadata.xml
index 78274e0fa550..1c3ba213c494 100644
--- a/games-board/atakks/metadata.xml
+++ b/games-board/atakks/metadata.xml
@@ -1,5 +1,5 @@
 <?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 <maintainer type="project">
 	<email>games@gentoo.org</email>