1 files changed, 49 insertions, 0 deletions
diff --git a/games-board/chessx/chessx-1.4.6.ebuild b/games-board/chessx/chessx-1.4.6.ebuild
new file mode 100644
index 000000000000..87b4a82b974f
--- /dev/null
+++ b/games-board/chessx/chessx-1.4.6.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop qmake-utils
+
+DESCRIPTION="Qt5-based Chess Database Utility"
+HOMEPAGE="http://chessx.sourceforge.net/"
+SRC_URI="https://sourceforge.net/projects/chessx/files/chessx/${PV}/${P}.tgz"
+
+LICENSE="GPL-2+ LGPL-2+ LGPL-2.1+ ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-libs/zlib:="
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.4.0-zlib.patch
+	"${FILESDIR}"/${P}-qt-5.11.patch
+)
+
+src_prepare() {
+	default
+	"$(qt5_get_bindir)/lrelease" i18n/* || die
+}
+
+src_configure() {
+	eqmake5
+}
+
+src_install() {
+	dobin release/${PN}
+	dodoc ChangeLog TODO
+	doicon data/images/${PN}.png
+	domenu unix/chessx.desktop
+}