4 files changed, 83 insertions, 0 deletions
diff --git a/games-puzzle/brainworkshop/Manifest b/games-puzzle/brainworkshop/Manifest
new file mode 100644
index 000000000000..becf83b71079
--- /dev/null
+++ b/games-puzzle/brainworkshop/Manifest
@@ -0,0 +1 @@
+DIST brainworkshop-4.8.4.zip 9373980 SHA256 bb1f259eda90e945a803524eedbc0087283e3fb9ae2ab4c16ded88c8c4e95b15 SHA512 d3819036fef98fab9a89637ba01b2d844146babc7cb34b6ec6f4a589c18a7532fd23cf083c867ea1c917df9d7a6507ab51a5942e745d3ab9d01d938812486936 WHIRLPOOL 4faf02832dc3af0f7c5fd0103996a884921433d2f3ff37d77d6c2510d7f6f3ab274dbe08c89f26e360725cb0ea3c52312cd23a813b680d330274579135fee2ef
diff --git a/games-puzzle/brainworkshop/brainworkshop-4.8.4.ebuild b/games-puzzle/brainworkshop/brainworkshop-4.8.4.ebuild
new file mode 100644
index 000000000000..d8e3e7e18743
--- /dev/null
+++ b/games-puzzle/brainworkshop/brainworkshop-4.8.4.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+inherit eutils gnome2-utils python-r1 games
+
+DESCRIPTION="Short-term-memory training N-Back game"
+HOMEPAGE="http://brainworkshop.sourceforge.net/"
+SRC_URI="mirror://sourceforge/brainworkshop/${P}.zip"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE=""
+
+RDEPEND="${PYTHON_DEPS}
+	dev-python/pyopenal
+	|| ( >=dev-python/pyglet-1.1.4[openal]
+		 >=dev-python/pyglet-1.1.4[alsa] )"
+DEPEND="app-arch/unzip"
+
+S=${WORKDIR}/${PN}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-fix-paths.patch
+	edos2unix ${PN}.pyw
+
+	sed -i \
+		-e 's#@GENTOO_DATADIR@#'${GAMES_DATADIR}'#' \
+		${PN}.pyw || die
+}
+
+src_install() {
+	newgamesbin ${PN}.pyw ${PN}
+	python_replicate_script "${D}${GAMES_BINDIR}"/${PN}
+	insinto "${GAMES_DATADIR}"/${PN}
+	doins -r res/*
+	dodoc Readme.txt data/Readme-stats.txt
+	newicon -s 48 res/misc/brain/brain.png ${PN}.png
+	make_desktop_entry ${PN} "Brain Workshop"
+	prepgamesdirs
+}
+
+pkg_preinst() {
+	games_pkg_preinst
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	games_pkg_postinst
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
diff --git a/games-puzzle/brainworkshop/files/brainworkshop-4.8.4-fix-paths.patch b/games-puzzle/brainworkshop/files/brainworkshop-4.8.4-fix-paths.patch
new file mode 100644
index 000000000000..061187b7cfe0
--- /dev/null
+++ b/games-puzzle/brainworkshop/files/brainworkshop-4.8.4-fix-paths.patch
@@ -0,0 +1,15 @@
+--- a/brainworkshop.pyw	2010-10-15 19:06:16.529006906 +0200
++++ b/brainworkshop.pyw	2010-10-15 19:08:17.095632136 +0200
+@@ -35,8 +35,10 @@
+ NOVBO = True
+ VSYNC = False
+ DEBUG = False
+-FOLDER_RES = 'res'
+-FOLDER_DATA = 'data'
++FOLDER_RES = '@GENTOO_DATADIR@/brainworkshop'
++FOLDER_DATA = os.path.expanduser('~/.brainworkshop')
++if not os.path.isdir(FOLDER_DATA):
++	os.mkdir(FOLDER_DATA)
+ CONFIGFILE = 'config.ini'
+ STATS_BINARY = 'logfile.dat'
+ USER = 'default'
diff --git a/games-puzzle/brainworkshop/metadata.xml b/games-puzzle/brainworkshop/metadata.xml
new file mode 100644
index 000000000000..6c54b4173f44
--- /dev/null
+++ b/games-puzzle/brainworkshop/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<herd>games</herd>
+	<upstream>
+		<remote-id type="sourceforge">brainworkshop</remote-id>
+	</upstream>
+</pkgmetadata>