1 files changed, 62 insertions, 0 deletions
diff --git a/games-puzzle/world-of-goo-hb/world-of-goo-hb-1.53.ebuild b/games-puzzle/world-of-goo-hb/world-of-goo-hb-1.53.ebuild
new file mode 100644
index 000000000000..e9b72ddc39b5
--- /dev/null
+++ b/games-puzzle/world-of-goo-hb/world-of-goo-hb-1.53.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop eutils		# eutils for make_wrapper()
+
+MY_PN="WorldOfGoo"
+
+DESCRIPTION="A puzzle game with a strong emphasis on physics (HumbleBundle edition)"
+HOMEPAGE="http://2dboy.com/"
+SRC_URI="${MY_PN}.Linux.${PV}.sh"
+
+LICENSE="2dboy-EULA"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="bundled-libs"
+RESTRICT="fetch bindist strip bundled-libs? ( splitdebug )"
+
+DEPEND="app-arch/unzip"
+RDEPEND="!bundled-libs? (
+		media-libs/libsdl2[alsa,sound,opengl,video]
+		media-libs/sdl2-mixer[vorbis]
+	)
+	sys-libs/glibc
+	virtual/opengl
+	virtual/glu
+	>=sys-devel/gcc-3.4
+	!games-puzzle/world-of-goo
+	!games-puzzle/world-of-goo-gog"
+
+dir="/opt/${PN%-*}"
+
+QA_PREBUILT="${dir:1}/${MY_PN}.bin.x86
+	${dir:1}/${MY_PN}.bin.x86_64"
+
+pkg_nofetch() {
+	elog "Download ${A} from www.humblebundle.com"
+	elog "and place it in your DISTDIR directory."
+}
+
+src_unpack() {
+	unzip -d "${S}" "${DISTDIR}/${A}"
+}
+
+src_install() {
+	exeinto "${dir}"
+	doexe data/x86$(usex amd64 _64)/${MY_PN}.bin.x86$(usex amd64 _64)
+
+	make_wrapper ${PN%-*} "${dir}"/${MY_PN}.bin.x86$(usex amd64 _64) \
+		$(use bundled-libs && (printf '"%s" "%s/lib%s"' "${dir}" "${dir}" $(usex amd64 64) || die))
+
+	insinto "${dir}"
+	doins -r data/noarch/game
+	use bundled-libs && doins -r data/x86$(usex amd64 _64)/lib$(usex amd64 64)
+	newicon data/noarch/game/gooicon.png ${PN%-*}.png
+
+	make_desktop_entry ${PN%-*} "World of Goo" ${PN%-*}
+
+	docinto html
+	dodoc data/noarch/readme.html
+}