1 files changed, 56 insertions, 0 deletions
diff --git a/mail-filter/rspamd/rspamd-1.0.11.ebuild b/mail-filter/rspamd/rspamd-1.0.11.ebuild
new file mode 100644
index 000000000000..54376f0c483f
--- /dev/null
+++ b/mail-filter/rspamd/rspamd-1.0.11.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit cmake-utils user
+
+DESCRIPTION="Rapid spam filtering system"
+SRC_URI="https://rspamd.com/downloads/${P}.tar.xz"
+HOMEPAGE="https://github.com/vstakhov/rspamd"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="dev-libs/libpcre
+		mail-filter/libmilter
+		mail-filter/opendkim
+		mail-filter/libspf2
+		dev-lang/luajit:2
+		dev-libs/libevent
+		dev-db/sqlite:3
+		dev-libs/glib:2
+		dev-libs/gmime
+		dev-libs/hiredis"
+RDEPEND="${DEPEND}"
+
+pkg_setup() {
+	enewgroup rspamd
+	enewuser rspamd -1 -1 /var/lib/rspamd rspamd
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCONFDIR=/etc/rspamd
+		-DRUNDIR=/var/run/rspamd
+		-DDBDIR=/var/lib/rspamd
+		-DLOGDIR=/var/log/rspamd
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	newinitd "${FILESDIR}/rspamd.init" rspamd
+
+	dodir /var/lib/rspamd
+	dodir /var/log/rspamd
+	dodir /var/run/rspamd
+	fowners rspamd:rspamd /var/lib/rspamd /var/log/rspamd /var/run/rspamd
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/rspamd.logrotate" rspamd
+}