1 files changed, 51 insertions, 0 deletions
diff --git a/media-video/ffmpegthumbnailer/ffmpegthumbnailer-2.2.0-r1.ebuild b/media-video/ffmpegthumbnailer/ffmpegthumbnailer-2.2.0-r1.ebuild
new file mode 100644
index 000000000000..c10e330b5787
--- /dev/null
+++ b/media-video/ffmpegthumbnailer/ffmpegthumbnailer-2.2.0-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils
+
+DESCRIPTION="Lightweight video thumbnailer that can be used by file managers"
+HOMEPAGE="https://github.com/dirkvdb/ffmpegthumbnailer"
+SRC_URI="https://github.com/dirkvdb/${PN}/releases/download/${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="alpha amd64 arm hppa ia64 ppc ppc64 sparc x86 ~x86-fbsd"
+IUSE="gnome gtk jpeg libav png test"
+
+REQUIRED_USE="gnome? ( gtk )
+	test? ( png jpeg )"
+
+BDEPEND="
+	virtual/pkgconfig
+"
+RDEPEND="
+	gtk? ( dev-libs/glib:2= )
+	jpeg? ( virtual/jpeg:0= )
+	!libav? ( >=media-video/ffmpeg-2.7:0= )
+	libav? ( >=media-video/libav-11:0= )
+	png? ( media-libs/libpng:0= )
+"
+DEPEND="${RDEPEND}"
+
+DOCS=( AUTHORS ChangeLog README.md )
+
+PATCHES=( "${FILESDIR}/${P}-pkgconfig-libdir.patch" )
+
+src_prepare() {
+	rm -rf out* || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_GIO=$(usex gtk)
+		-DENABLE_TESTS=$(usex test)
+		-DENABLE_THUMBNAILER=$(usex gnome)
+		-DHAVE_JPEG=$(usex jpeg)
+		-DHAVE_PNG=$(usex png)
+	)
+	cmake-utils_src_configure
+}