1 files changed, 52 insertions, 0 deletions
diff --git a/net-analyzer/prometheus-alertmanager/prometheus-alertmanager-0.9.1.ebuild b/net-analyzer/prometheus-alertmanager/prometheus-alertmanager-0.9.1.ebuild
new file mode 100644
index 000000000000..d04d5de449d7
--- /dev/null
+++ b/net-analyzer/prometheus-alertmanager/prometheus-alertmanager-0.9.1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit user golang-build golang-vcs-snapshot
+
+EGO_PN="github.com/prometheus/alertmanager"
+EGIT_COMMIT="v${PV/_rc/-rc.}"
+ALERTMANAGER_COMMIT="9f5f4b2"
+ARCHIVE_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+KEYWORDS="~amd64"
+
+DESCRIPTION="Alertmanager for alerts sent by client applications such as Prometheus"
+HOMEPAGE="https://github.com/prometheus/alertmanager"
+SRC_URI="${ARCHIVE_URI}"
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE=""
+
+DEPEND="dev-util/promu"
+
+RESTRICT="test"
+
+pkg_setup() {
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 -1 ${PN}
+}
+
+src_prepare() {
+	default
+	sed -i -e "s/{{.Revision}}/${ALERTMANAGER_COMMIT}/" src/${EGO_PN}/.promu.yml || die
+}
+
+src_compile() {
+	pushd src/${EGO_PN} || die
+	mkdir -p bin || die
+	GOPATH="${S}" promu build -v --prefix alertmanager || die
+	popd || die
+}
+
+src_install() {
+	pushd src/${EGO_PN} || die
+	dobin alertmanager/alertmanager
+	dodoc {README,CHANGELOG,CONTRIBUTING}.md
+	insinto /etc/alertmanager/
+	newins doc/examples/simple.yml config.yml.example
+	popd || die
+	keepdir /var/lib/alertmanager /var/log/alertmanager
+	fowners ${PN}:${PN} /var/lib/alertmanager /var/log/alertmanager
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+}