2 files changed, 60 insertions, 3 deletions
diff --git a/sci-electronics/systemc/systemc-2.3.4-r1.ebuild b/sci-electronics/systemc/systemc-2.3.4-r1.ebuild
index 4669cd8f6d9b..ad0a4ea125bb 100644
--- a/sci-electronics/systemc/systemc-2.3.4-r1.ebuild
+++ b/sci-electronics/systemc/systemc-2.3.4-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -18,7 +18,7 @@ if [[ "${PV}" == "9999" ]] ; then
 	inherit git-r3
 else
 	SRC_URI="https://github.com/accellera-official/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+	KEYWORDS="amd64 ~arm ~arm64 ~x86"
 	S="${WORKDIR}/${PN}-${MY_PV}"
 fi
 
@@ -34,7 +34,7 @@ src_prepare() {
 }
 
 src_configure() {
-	econf CXX=$(tc-getCXX) \
+	econf CXX="$(tc-getCXX)" \
 		$(use_enable debug) \
 		$(use_enable static-libs static) \
 		--with-unix-layout
diff --git a/sci-electronics/systemc/systemc-2.3.4-r2.ebuild b/sci-electronics/systemc/systemc-2.3.4-r2.ebuild
new file mode 100644
index 000000000000..098270948b4f
--- /dev/null
+++ b/sci-electronics/systemc/systemc-2.3.4-r2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PV="${PV}_pub_rev_20190614"
+
+inherit autotools toolchain-funcs
+
+DESCRIPTION="A C++ based modeling platform for VLSI and system-level co-design"
+HOMEPAGE="
+	https://systemc.org
+	https://github.com/accellera-official/systemc
+"
+
+if [[ "${PV}" == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/accellera-official/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/accellera-official/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="amd64 ~arm ~arm64 ~x86"
+	S="${WORKDIR}/${PN}-${MY_PV}"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="debug doc examples static-libs"
+REQUIRED_USE="examples? ( doc )"
+
+src_prepare() {
+	default
+	eautoconf --force
+}
+
+src_configure() {
+	econf CXX="$(tc-getCXX)" \
+		$(use_enable debug) \
+		$(use_enable static-libs static) \
+		--with-unix-layout
+}
+
+src_install() {
+	default
+	if use doc; then
+		if use examples; then
+			docompress -x /usr/share/doc/"${PF}"/examples
+		else
+			rm -r "${ED}"/usr/share/doc/"${PF}"/examples || die
+		fi
+	else
+		rm -r "${ED}"/usr/share/doc/"${PF}" || die
+	fi
+
+	if ! use static-libs; then
+		find "${ED}" -name "*.la" -delete || die
+	fi
+}