1 files changed, 62 insertions, 0 deletions
diff --git a/sci-physics/herwig/herwig-6.5.10.ebuild b/sci-physics/herwig/herwig-6.5.10.ebuild
new file mode 100644
index 000000000000..4de4376e4b8f
--- /dev/null
+++ b/sci-physics/herwig/herwig-6.5.10.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=2
+
+inherit versionator autotools fortran-2
+
+PV1=$(get_version_component_range 1 ${PV})
+PV2=$(get_version_component_range 2 ${PV})
+PV3=$(get_version_component_range 3 ${PV})
+MY_VER=${PV1}${PV2}${PV3}
+MY_P=${PN}${MY_VER}
+MY_PINC="$(echo ${PN}|tr '[:lower:]' '[:upper:]')${PV1}${PV2}.INC"
+
+DESCRIPTION="High Energy Physics Event Generator"
+HOMEPAGE="http://www.hep.phy.cam.ac.uk/theory/webber/Herwig/"
+SRC_URI="
+	${HOMEPAGE}/${MY_P}.f
+	${HOMEPAGE}/${MY_P}.inc
+	${HOMEPAGE}/${MY_PINC}"
+
+LICENSE="all-rights-reserved"
+RESTRICT="mirror bindist"
+
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE=""
+
+DEPEND="!sci-physics/cernlib-montecarlo[herwig]"
+RDEPEND=""
+
+S="${WORKDIR}"
+
+src_unpack() {
+	cp "${DISTDIR}"/* "${S}"
+}
+
+src_prepare() {
+	sed -i "s/6521/${MY_VER}/" "${MY_PINC}" || die
+	cat > configure.ac <<-EOF
+		AC_INIT(${PN},${PV})
+		AM_INIT_AUTOMAKE
+		AC_PROG_F77
+		AC_PROG_LIBTOOL
+		AC_CONFIG_FILES(Makefile)
+		AC_OUTPUT
+	EOF
+	cat > Makefile.am <<-EOF
+		lib_LTLIBRARIES = lib${PN}.la
+		lib${PN}_la_SOURCES = ${MY_P}.f
+		pkginclude_HEADERS = \
+			${MY_PINC} \
+			${MY_P}.inc
+
+	EOF
+	eautoreconf
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+}