1 files changed, 55 insertions, 0 deletions
diff --git a/sys-apps/acl/acl-2.3.2-r1.ebuild b/sys-apps/acl/acl-2.3.2-r1.ebuild
new file mode 100644
index 000000000000..d265f5bd1bbe
--- /dev/null
+++ b/sys-apps/acl/acl-2.3.2-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic libtool multilib-minimal
+
+DESCRIPTION="Access control list utilities, libraries, and headers"
+HOMEPAGE="https://savannah.nongnu.org/projects/acl"
+SRC_URI="mirror://nongnu/${PN}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+ GPL-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux"
+IUSE="nls static-libs"
+
+RDEPEND="
+	>=sys-apps/attr-2.4.47-r1[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	default
+
+	# bug #580792
+	elibtoolize
+}
+
+multilib_src_configure() {
+	# Filter out -flto flags as they break getfacl/setfacl binaries (bug #667372)
+	filter-lto
+
+	local myeconfargs=(
+		--bindir="${EPREFIX}"/bin
+		--libexecdir="${EPREFIX}"/usr/$(get_libdir)
+		--enable-largefile
+		$(use_enable static-libs static)
+		$(use_enable nls)
+	)
+
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_test() {
+	# Tests call native binaries with an LD_PRELOAD wrapper
+	# bug #772356
+	multilib_is_native_abi && default
+}
+
+multilib_src_install_all() {
+	if ! use static-libs ; then
+		find "${ED}" -type f -name "*.la" -delete || die
+	fi
+}