1 files changed, 38 insertions, 0 deletions
diff --git a/sys-devel/lld-toolchain-symlinks/lld-toolchain-symlinks-16-r2.ebuild b/sys-devel/lld-toolchain-symlinks/lld-toolchain-symlinks-16-r2.ebuild
new file mode 100644
index 000000000000..2eb282b65da9
--- /dev/null
+++ b/sys-devel/lld-toolchain-symlinks/lld-toolchain-symlinks-16-r2.ebuild
@@ -0,0 +1,38 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit multilib
+
+DESCRIPTION="Symlinks to use LLD on binutils-free system"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:LLVM"
+S=${WORKDIR}
+
+LICENSE="public-domain"
+SLOT="${PV}"
+KEYWORDS="amd64 arm arm64 ~ppc ppc64 ~riscv x86 ~arm64-macos"
+IUSE="multilib-symlinks +native-symlinks"
+
+RDEPEND="
+	sys-devel/lld:${SLOT}
+"
+
+src_install() {
+	use native-symlinks || return
+
+	local chosts=( "${CHOST}" )
+	if use multilib-symlinks; then
+		local abi
+		for abi in $(get_all_abis); do
+			chosts+=( "$(get_abi_CHOST "${abi}")" )
+		done
+	fi
+
+	local dest=/usr/lib/llvm/${SLOT}/bin
+	dodir "${dest}"
+	dosym ld.lld "${dest}/ld"
+	for chost in "${chosts[@]}"; do
+		dosym ld.lld "${dest}/${chost}-ld"
+	done
+}