1 files changed, 49 insertions, 0 deletions
diff --git a/sys-devel/make/make-4.2.ebuild b/sys-devel/make/make-4.2.ebuild
new file mode 100644
index 000000000000..c57efdec84a9
--- /dev/null
+++ b/sys-devel/make/make-4.2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit flag-o-matic eutils
+
+DESCRIPTION="Standard tool to compile source trees"
+HOMEPAGE="https://www.gnu.org/software/make/make.html"
+SRC_URI="mirror://gnu//make/${P}.tar.bz2"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="guile nls static"
+
+CDEPEND="guile? ( >=dev-scheme/guile-1.8:= )"
+DEPEND="${CDEPEND}
+	nls? ( sys-devel/gettext )"
+RDEPEND="${CDEPEND}
+	nls? ( virtual/libintl )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.82-darwin-library_search-dylib.patch
+)
+
+src_prepare() {
+	epatch "${PATCHES[@]}"
+}
+
+src_configure() {
+	use static && append-ldflags -static
+	econf \
+		--program-prefix=g \
+		$(use_with guile) \
+		$(use_enable nls)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS NEWS README*
+	if [[ ${USERLAND} == "GNU" ]] ; then
+		# we install everywhere as 'gmake' but on GNU systems,
+		# symlink 'make' to 'gmake'
+		dosym gmake /usr/bin/make
+		dosym gmake.1 /usr/share/man/man1/make.1
+	fi
+}