1 files changed, 0 insertions, 85 deletions
diff --git a/sys-kernel/aufs-sources/aufs-sources-3.18.31.ebuild b/sys-kernel/aufs-sources/aufs-sources-3.18.31.ebuild
deleted file mode 100644
index e1101753d5ee..000000000000
--- a/sys-kernel/aufs-sources/aufs-sources-3.18.31.ebuild
+++ /dev/null
@@ -1,85 +0,0 @@
-# Copyright 1999-2016 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI=5
-
-ETYPE="sources"
-K_WANT_GENPATCHES="base extras experimental"
-K_GENPATCHES_VER="32"
-K_DEBLOB_AVAILABLE="0"
-UNIPATCH_STRICTORDER=1
-inherit kernel-2 eutils readme.gentoo-r1
-detect_version
-detect_arch
-
-AUFS_VERSION=3.18.25+_p20160328
-AUFS_TARBALL="aufs-sources-${AUFS_VERSION}.tar.xz"
-# git archive -v --remote=git://git.code.sf.net/p/aufs/aufs3-standalone aufs${AUFS_VERSION/_p*} > aufs-sources-${AUFS_VERSION}.tar
-AUFS_URI="https://dev.gentoo.org/~jlec/distfiles/${AUFS_TARBALL}"
-
-KEYWORDS="~amd64 ~x86"
-HOMEPAGE="https://dev.gentoo.org/~mpagano/genpatches http://aufs.sourceforge.net/"
-IUSE="deblob experimental module vanilla"
-
-DESCRIPTION="Full sources including the Gentoo patchset for the ${KV_MAJOR}.${KV_MINOR} kernel tree and aufs3 support"
-SRC_URI="
-	${KERNEL_URI}
-	${ARCH_URI}
-	${AUFS_URI}
-	!vanilla? ( ${GENPATCHES_URI} )
-	"
-
-PDEPEND="=sys-fs/aufs-util-3*"
-
-README_GENTOO_SUFFIX="-r1"
-
-src_unpack() {
-	if use vanilla; then
-		unset UNIPATCH_LIST_GENPATCHES UNIPATCH_LIST_DEFAULT
-		ewarn "You are using USE=vanilla"
-		ewarn "This will drop all support from the gentoo kernel security team"
-	fi
-
-	UNIPATCH_LIST="
-		"${WORKDIR}"/aufs3-kbuild.patch
-		"${WORKDIR}"/aufs3-base.patch
-		"${WORKDIR}"/aufs3-mmap.patch"
-
-	use module && UNIPATCH_LIST+=" "${WORKDIR}"/aufs3-standalone.patch"
-
-	unpack ${AUFS_TARBALL}
-
-	einfo "Using aufs3 version: ${AUFS_VERSION}"
-
-	kernel-2_src_unpack
-}
-
-src_prepare() {
-	if ! use module; then
-		sed -e 's:tristate:bool:g' -i "${WORKDIR}"/fs/aufs/Kconfig || die
-	fi
-	cp -f "${WORKDIR}"/include/uapi/linux/aufs_type.h include/uapi/linux/aufs_type.h || die
-	cp -rf "${WORKDIR}"/{Documentation,fs} . || die
-}
-
-src_install() {
-	kernel-2_src_install
-	dodoc "${WORKDIR}"/{aufs3-loopback,vfs-ino,tmpfs-idr}.patch
-	docompress -x /usr/share/doc/${PF}/{aufs3-loopback,vfs-ino,tmpfs-idr}.patch
-	readme.gentoo_create_doc
-}
-
-pkg_postinst() {
-	kernel-2_pkg_postinst
-	einfo "For more info on this patchset, and how to report problems, see:"
-	einfo "${HOMEPAGE}"
-	has_version sys-fs/aufs-util || \
-		elog "In order to use aufs FS you need to install sys-fs/aufs-util"
-
-	readme.gentoo_print_elog
-}
-
-pkg_postrm() {
-	kernel-2_pkg_postrm
-}