1 files changed, 34 insertions, 0 deletions
diff --git a/sys-libs/librtas/librtas-2.0.2-r2.ebuild b/sys-libs/librtas/librtas-2.0.2-r2.ebuild
new file mode 100644
index 000000000000..f43d44b267f5
--- /dev/null
+++ b/sys-libs/librtas/librtas-2.0.2-r2.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools
+
+DESCRIPTION="A set of libraries for userspace access to RTAS on the PowerPC platform(s)"
+HOMEPAGE="https://github.com/ibm-power-utilities/librtas"
+SRC_URI="https://github.com/ibm-power-utilities/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="ppc ppc64 ~ppc64-linux"
+IUSE="static-libs"
+
+PATCHES=( "${FILESDIR}"/${P}-musl.patch )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_enable static-libs static)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install docdir="${EPREFIX}"/usr/share/doc/${PF}
+	find "${D}" -name '*.la' -delete || die
+	# librtas_src/syscall_rmo.c: static const char *lockfile_path = "/var/lock/LCK..librtas";
+	# this way we prevent sandbox violations in lscpu linked to rtas
+	dodir /etc/sandbox.d
+	echo 'SANDBOX_PREDICT="/run/lock/LCK..librtas"' > "${ED}"/etc/sandbox.d/50librtas || die
+}