1 files changed, 66 insertions, 0 deletions
diff --git a/www-servers/tornado/tornado-4.4.1.ebuild b/www-servers/tornado/tornado-4.4.1.ebuild
new file mode 100644
index 000000000000..520d50c532d8
--- /dev/null
+++ b/www-servers/tornado/tornado-4.4.1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python web framework and asynchronous networking library"
+HOMEPAGE="http://www.tornadoweb.org/ https://pypi.python.org/pypi/tornado"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+
+CDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	>=dev-python/pycurl-7.19.3.1[${PYTHON_USEDEP}]
+	dev-python/backports-ssl-match-hostname[${PYTHON_USEDEP}]
+	|| (
+		(	$(python_gen_cond_dep 'dev-python/twisted-names[${PYTHON_USEDEP}]' 'python2_7')
+			$(python_gen_cond_dep 'dev-python/twisted-web[${PYTHON_USEDEP}]' 'python2_7')
+		)
+		>=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
+	)
+	virtual/python-backports_abc[${PYTHON_USEDEP}]
+	virtual/python-futures[${PYTHON_USEDEP}]
+	virtual/python-singledispatch[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)
+	test? (
+		${CDEPEND}
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="${CDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/4.4-drop-intersphinx.patch
+	"${FILESDIR}"/4.4.1-options-test.patch
+)
+
+python_compile_all() {
+	use doc && emake -C docs sphinx
+}
+
+python_test() {
+	"${PYTHON}" -m tornado.test.runtests || die "tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	use examples && local EXAMPLES=( demos/. )
+
+	distutils-r1_python_install_all
+}