2 files changed, 79 insertions, 0 deletions
diff --git a/xfce-extra/xfce4-screenshooter/Manifest b/xfce-extra/xfce4-screenshooter/Manifest
index b95c47c14e8d..d4bf1c8d30f9 100644
--- a/xfce-extra/xfce4-screenshooter/Manifest
+++ b/xfce-extra/xfce4-screenshooter/Manifest
@@ -1 +1,2 @@
 DIST xfce4-screenshooter-1.10.5.tar.bz2 621929 BLAKE2B 616feb84dc6eabbf964d4b31a6604fb8bea6e5a23a4f52d1fbb18775e0b2859cfe12c70a18cdd82e62324c386990f5cd114659d5259cac5a22499e8d5eda4423 SHA512 0040b28514ffc77473b2d9f182c1bc162f8ac21aac97f2e28eb2b5556255dd74f7d4545f049b4060a8db6c0d415831fe5988da581857f22894bed01136aee677
+DIST xfce4-screenshooter-1.10.6.tar.bz2 813187 BLAKE2B 2f5d12cd1879d35911fee159e909f8b64970831fdd350fd46ca64371376592d30db8658d03045cc84d52ce16c19ec374dcb926b0151fcfc35e365832eb3b8803 SHA512 2984ff3a64d0783c62ad5ac33ef54f4ec70fb6d06ac66f4a963940878d04b5e77c100a8121b73788ce6cc0af427fec9d5bf09235465b3591cd57cd16c7d9cda2
diff --git a/xfce-extra/xfce4-screenshooter/xfce4-screenshooter-1.10.6.ebuild b/xfce-extra/xfce4-screenshooter/xfce4-screenshooter-1.10.6.ebuild
new file mode 100644
index 000000000000..3cab24e6a56a
--- /dev/null
+++ b/xfce-extra/xfce4-screenshooter/xfce4-screenshooter-1.10.6.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg-utils
+
+DESCRIPTION="Xfce4 screenshooter application and panel plugin"
+HOMEPAGE="
+	https://docs.xfce.org/apps/xfce4-screenshooter/start
+	https://gitlab.xfce.org/apps/xfce4-screenshooter/
+"
+SRC_URI="https://archive.xfce.org/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="X wayland"
+REQUIRED_USE="|| ( X wayland )"
+
+DEPEND="
+	>=dev-libs/glib-2.66.0
+	>=x11-libs/gdk-pixbuf-2.16
+	>=x11-libs/gtk+-3.24.0:3[X?,wayland?]
+	>=x11-libs/pango-1.44.0
+	dev-libs/libxml2
+	>=net-libs/libsoup-3.0.0:3.0
+	>=xfce-base/exo-0.11:=
+	>=xfce-base/xfce4-panel-4.16.0:=
+	>=xfce-base/libxfce4util-4.16.0:=
+	>=xfce-base/libxfce4ui-4.16.0:=
+	>=xfce-base/xfconf-4.16.0:=
+	wayland? (
+		dev-libs/wayland
+	)
+	X? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXfixes
+		>=x11-libs/libXi-1.7.8
+		x11-libs/libXtst
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-util/glib-utils
+	sys-apps/help2man
+	sys-devel/gettext
+	virtual/pkgconfig
+	wayland? (
+		dev-util/wayland-scanner
+	)
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable X x11)
+		$(use_enable X libxtst)
+		$(use_enable wayland)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}