blob: 0adc88086a0f4789a464d379acf6a8ecfa8ecec5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..10} )
DISTUTILS_SINGLE_IMPL=1
inherit distutils-r1 optfeature
MY_PN="${PN#ansible-}"
MY_P="${MY_PN}-${PV}"
DESCRIPTION="A toolkit designed to aid in the development and testing of Ansible roles"
HOMEPAGE="https://pypi.org/project/molecule/ https://github.com/ansible-community/molecule/"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE="selinux"
RDEPEND="$(python_gen_cond_dep '
>=dev-python/ansible-compat-0.5.0[${PYTHON_USEDEP}]
<dev-python/cerberus-1.3.3[${PYTHON_USEDEP}]
>=dev-python/click-8.0[${PYTHON_USEDEP}]
>=dev-python/click-help-colors-0.9[${PYTHON_USEDEP}]
>=dev-python/enrich-1.2.5[${PYTHON_USEDEP}]
>=dev-python/jinja-2.11.3[${PYTHON_USEDEP}]
dev-python/packaging[${PYTHON_USEDEP}]
<dev-python/paramiko-3[${PYTHON_USEDEP}]
<dev-python/pluggy-2.0[${PYTHON_USEDEP}]
>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
>=dev-python/rich-9.5.1[${PYTHON_USEDEP}]
>=dev-python/subprocess-tee-0.3.5[${PYTHON_USEDEP}]
>=dev-util/cookiecutter-1.7.3[${PYTHON_USEDEP}]
selinux? ( sys-libs/libselinux[python,${PYTHON_USEDEP}] )
')"
BDEPEND="$(python_gen_cond_dep '
>=dev-python/setuptools_scm-3.5.0[${PYTHON_USEDEP}]
>=dev-python/setuptools_scm_git_archive-1.1[${PYTHON_USEDEP}]
doc? (
dev-python/ansible-pygments[${PYTHON_USEDEP}]
>=dev-python/simplejson-3.17.2[${PYTHON_USEDEP}]
)
test? (
>=dev-python/ansi2html-1.6.0[${PYTHON_USEDEP}]
<dev-python/pexpect-5[${PYTHON_USEDEP}]
>=dev-python/pytest-html-3.0.0[${PYTHON_USEDEP}]
>=dev-python/pytest-mock-3.3.1[${PYTHON_USEDEP}]
>=dev-python/pytest-plus-0.2[${PYTHON_USEDEP}]
>=dev-python/pytest-testinfra-6.1.0[${PYTHON_USEDEP}]
>=dev-python/pytest-xdist-2.1.0[${PYTHON_USEDEP}]
dev-util/yamllint
)
')"
PATCHES=(
"${FILESDIR}"/${PN}-3.5.2_pyyaml6.patch
)
S="${WORKDIR}"/${MY_P}
distutils_enable_sphinx docs '>=dev-python/sphinx-notfound-page-0.7.1' '<dev-python/sphinx_ansible_theme-0.9.0'
distutils_enable_tests --install pytest
src_prepare() {
default
if ! use selinux; then
sed -i "/^\s\+selinux/d" setup.cfg || die "Failed to remove dependency on SELinux"
fi
# Several issues with tests from this file:
# - quite a few of these use the network;
# - test_command_dependency[shell] only works if Molecule has previously been installed;
# - tests involving creation of a new scenario fail on ansible-lint errors, even though
# a config file is deployed which should skip expected issues.
rm -f src/molecule/test/functional/test_command.py
}
python_test() {
distutils_install_for_testing --via-venv
distutils-r1_python_test
}
pkg_postinst() {
optfeature_header "Some optional packages commonly used in Molecule scenarios:"
optfeature "checking playbooks for practices and behaviour that can be improved" app-admin/ansible-lint
}
|
GitWeb