blob: 9c9a6edff6c4d98bf4a528e0638cf948ce593304 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit bash-completion-r1 golang-vcs-snapshot
DESCRIPTION="A backup program that is fast, efficient and secure"
HOMEPAGE="https://restic.github.io/"
SRC_URI="https://github.com/restic/restic/archive/v${PV}.tar.gz -> ${P}.tar.gz"
EGO_PN="github.com/restic/restic"
LICENSE="Apache-2.0 BSD BSD-2 LGPL-3-with-linking-exception MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE=""
RDEPEND="sys-fs/fuse:0"
DEPEND="${RDEPEND}"
S="${WORKDIR}/${P}/src/${EGO_PN}"
src_compile() {
local mygoargs=(
-v
-work
-x
-tags release
-ldflags "-X main.version=${PV}"
-asmflags "-trimpath=${S}"
-gcflags "-trimpath=${S}"
-o restic ${EGO_PN}/cmd/restic
)
GO111MODULE=off GOPATH="${WORKDIR}/${P}:$(get_golibdir_gopath)" \
go build "${mygoargs[@]}" || die
}
src_test() {
GO111MODULE=off GOPATH="${WORKDIR}/${P}:$(get_golibdir_gopath)" \
go test -timeout 30m -v -work -x ${EGO_PN}/cmd/... ${EGO_PN}/internal/... || die
}
src_install() {
dobin restic
newbashcomp doc/bash-completion.sh "${PN}"
insinto /usr/share/zsh/site-functions
newins doc/zsh-completion.zsh _restic
doman doc/man/*
dodoc doc/*.rst
}
|
GitWeb
