blob: 6652a82c38c25b35435089a501b1e778670734c2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools udev
DESCRIPTION="CCID free software driver"
HOMEPAGE="https://ccid.apdu.fr https://github.com/LudovicRousseau/CCID"
SRC_URI="https://ccid.apdu.fr/files/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~ia64 ppc ppc64 ~riscv ~sparc x86"
IUSE="twinserial +usb"
RDEPEND="
>=sys-apps/pcsc-lite-1.8.3
twinserial? ( dev-lang/perl )
usb? ( virtual/libusb:1 )
"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
PATCHES=(
"${FILESDIR}"/${P}-remove-flex-configure-dependency.patch
)
src_prepare() {
default
eautoconf
}
src_configure() {
econf \
LEX=: \
$(use_enable twinserial) \
$(use_enable usb libusb)
}
src_install() {
default
udev_newrules src/92_pcscd_ccid.rules 92-pcsc-ccid.rules
}
pkg_postinst() {
udev_reload
einfo "Check https://github.com/LudovicRousseau/CCID/blob/master/INSTALL"
einfo "for more info about how to configure and use ccid"
}
pkg_postrm() {
udev_reload
}
|
GitWeb
