blob: d5fd9c40165a86b17e99af00ea2c55153645120e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
inherit toolchain-funcs multilib-minimal
DESCRIPTION="Console utility and library for computing and verifying file hash sums"
HOMEPAGE="http://rhash.anz.ru/"
SRC_URI="mirror://sourceforge/${PN}/${P}-src.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc64 ~x86"
IUSE="debug nls openssl static-libs"
RDEPEND="openssl? ( dev-libs/openssl:0=[${MULTILIB_USEDEP}] )"
DEPEND="${RDEPEND}
nls? ( sys-devel/gettext )"
src_prepare() {
default
# Exit on test failure or src_test will always succeed.
sed -i "s/return 1/exit 1/g" tests/test_rhash.sh || die
multilib_copy_sources
}
multilib_src_compile() {
local ADDCFLAGS=(
$(use debug || echo -DNDEBUG)
$(use nls && echo -DUSE_GETTEXT)
$(use openssl && echo -DOPENSSL_RUNTIME -rdynamic)
)
local ADDLDFLAGS=(
$(use openssl && echo -ldl)
)
emake CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}" CC="$(tc-getCC)" \
ADDCFLAGS="${ADDCFLAGS[*]}" ADDLDFLAGS="${ADDLDFLAGS[*]}" \
build-shared $(use static-libs && echo lib-static)
}
myemake() {
emake DESTDIR="${D}" PREFIX="${EPREFIX}"/usr LIBDIR='$(PREFIX)'/$(get_libdir) "${@}"
}
multilib_src_install() {
myemake -C librhash install-lib-shared install-so-link
multilib_is_native_abi && myemake install-shared
use static-libs && myemake install-lib-static
}
multilib_src_install_all() {
myemake -C librhash install-headers
use nls && myemake install-gmo
einstalldocs
}
multilib_src_test() {
cd tests || die
LD_LIBRARY_PATH=$(pwd)/../librhash ./test_rhash.sh --full ../rhash_shared || die "tests failed"
}
|
GitWeb
