blob: eb05b36e0f16da575d5460d74234933aec2de3f7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{7,8} )
inherit autotools distutils-r1
DESCRIPTION="Libtpms-based TPM emulator"
HOMEPAGE="https://github.com/stefanberger/swtpm"
SRC_URI="https://github.com/stefanberger/swtpm/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64"
IUSE="fuse gnutls libressl seccomp test"
RESTRICT="!test? ( test )"
COMMON_DEPEND="
fuse? (
dev-libs/glib:2
sys-fs/fuse:0
)
gnutls? (
dev-libs/libtasn1:=
>=net-libs/gnutls-3.1.0[tools]
)
!libressl? (
dev-libs/openssl:0=
dev-libs/libtpms[-libressl]
)
libressl? (
dev-libs/libressl:0=
dev-libs/libtpms[libressl]
)
seccomp? ( sys-libs/libseccomp )
"
DEPEND="${COMMON_DEPEND}
test? (
net-misc/socat
dev-tcltk/expect
${PYTHON_DEPS}
)
"
RDEPEND="${COMMON_DEPEND}
acct-group/tss
acct-user/tss
dev-python/cryptography[${PYTHON_USEDEP}]
"
PATCHES=(
"${FILESDIR}/${PN}-0.5.0-fix-localca-path.patch"
"${FILESDIR}/${PN}-0.5.0-build-sys-Remove-WError.patch"
)
src_prepare() {
use test || eapply "${FILESDIR}/${PN}-0.5.0-disable-test-dependencies.patch"
default
eautoreconf
eautomake
}
src_configure() {
econf \
--disable-static \
--with-openssl \
--without-selinux \
$(use_with fuse cuse) \
$(use_with gnutls) \
$(use_with seccomp)
}
src_compile() {
# We want the default src_compile, not the version distutils-r1 exports
default
}
src_install() {
default
python_foreach_impl python_optimize
fowners -R tss:root /var/lib/swtpm-localca
fperms 750 /var/lib/swtpm-localca
keepdir /var/lib/swtpm-localca
find "${D}" -name '*.la' -delete || die
}
src_test() {
# We want the default src_test, not the version distutils-r1 exports
default
}
|
GitWeb