blob: 5f04a6ad831c09da71e6d3a10082f0b0fbb78370 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
NEED_EMACS=26.1
DISTUTILS_USE_PEP517=no
PYTHON_COMPAT=( python3_{10..12} )
inherit distutils-r1 elisp
DESCRIPTION="Tree style project file explorer"
HOMEPAGE="https://github.com/Alexander-Miller/treemacs/"
if [[ "${PV}" == *9999* ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/Alexander-Miller/${PN}.git"
else
SRC_URI="https://github.com/Alexander-Miller/${PN}/archive/${PV}.tar.gz
-> ${P}.tar.gz"
KEYWORDS="~amd64"
fi
LICENSE="GPL-3+"
SLOT="0"
RDEPEND="
>=app-editors/emacs-${NEED_EMACS}[svg]
app-emacs/ace-window
app-emacs/cfrs
app-emacs/dash
app-emacs/ht
app-emacs/hydra
app-emacs/pfuture
app-emacs/s
"
BDEPEND="
${RDEPEND}
"
BYTECOMPFLAGS="-L . -L src/elisp"
PATCHES=(
"${FILESDIR}/${PN}-2.9.5-tests.patch"
"${FILESDIR}/${PN}-async-scripts.patch"
"${FILESDIR}/${PN}-icons-icon-directory.patch"
)
DOCS=( Changelog.org Extensions.org README.org screenshots )
SITEFILE="50${PN}-gentoo.el"
elisp-enable-tests buttercup test
src_prepare() {
distutils-r1_src_prepare
sed "s|@SITEETC@|${SITEETC}/${PN}|g" \
-i "src/elisp/${PN}-icons.el" \
-i "src/elisp/${PN}-async.el" || die
}
python_compile() {
python_optimize "${S}/src/scripts"
}
src_compile() {
distutils-r1_src_compile
elisp-compile src/elisp/*.el
}
src_install() {
elisp-install "${PN}" src/elisp/*.el{,c}
elisp-site-file-install "${FILESDIR}/${SITEFILE}"
insinto "${SITEETC}/${PN}"
doins -r icons
doins -r src/scripts
}
|
GitWeb