app-emacs/web-server/web-server-0.1.2_p20210708-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

COMMIT=6357a1c2d1718778503f7ee0909585094117525b

inherit elisp

DESCRIPTION="Web server running Emacs Lisp handlers"
HOMEPAGE="https://github.com/eschulte/emacs-web-server/"

if [[ ${PV} == *9999* ]] ; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/eschulte/emacs-${PN}.git"
else
	SRC_URI="https://github.com/eschulte/emacs-${PN}/archive/${COMMIT}.tar.gz
		-> ${P}.tar.gz"
	S="${WORKDIR}"/emacs-${PN}-${COMMIT}
	KEYWORDS="~amd64 ~x86"
fi

LICENSE="GPL-3+"
SLOT="0"
PROPERTIES="test_network"
RESTRICT="test"

BDEPEND="sys-apps/texinfo"

DOCS=( README NOTES )
SITEFILE="50${PN}-gentoo.el"

src_compile() {
	elisp_src_compile

	emake -C doc
}

src_test() {
	emake EMACS=${EMACS} check
}

src_install() {
	elisp_src_install

	doinfo doc/${PN}.info
	dodoc doc/${PN}_html/*

	insinto ${SITEETC}/${PN}
	doins -r examples
}