blob: 04008dcbd0bd314fca7e7f7b587bdeafde0ae4a0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=5
PYTHON_COMPAT=( python2_7 )
inherit eutils systemd user toolchain-funcs python-any-r1
DESCRIPTION="An Open Source MQTT v3 Broker"
HOMEPAGE="http://mosquitto.org/"
SRC_URI="http://mosquitto.org/files/source/${P}.tar.gz"
LICENSE="EPL-1.0"
SLOT="0"
KEYWORDS="amd64 arm x86"
IUSE="bridge examples +persistence +srv ssl tcpd websockets"
RDEPEND="tcpd? ( sys-apps/tcp-wrappers )
ssl? ( dev-libs/openssl:0= )"
DEPEND="${RDEPEND}
${PYTHON_DEPS}
srv? ( net-dns/c-ares )
websockets? ( net-libs/libwebsockets )"
pkg_setup() {
enewgroup mosquitto
enewuser mosquitto -1 -1 -1 mosquitto
}
src_prepare() {
epatch "${FILESDIR}/${PN}-1.4.10-conditional-tests.patch"
if use persistence; then
sed -i -e "s:^#autosave_interval:autosave_interval:" \
-e "s:^#persistence false$:persistence true:" \
-e "s:^#persistence_file:persistence_file:" \
-e "s:^#persistence_location$:persistence_location /var/lib/mosquitto/:" \
mosquitto.conf || die
fi
# Remove prestripping
sed -i -e 's/-s --strip-program=${CROSS_COMPILE}${STRIP}//'\
client/Makefile lib/cpp/Makefile src/Makefile lib/Makefile || die
python_setup
python_fix_shebang test
}
src_configure() {
LIBDIR=$(get_libdir)
makeopts=(
"CC=$(tc-getCC)"
"LIB_SUFFIX=${LIBDIR:3}"
"WITH_BRIDGE=$(usex bridge)"
"WITH_PERSISTENCE=$(usex persistence)"
"WITH_SRV=$(usex srv)"
"WITH_TLS=$(usex ssl)"
"WITH_WEBSOCKETS=$(usex websockets)"
"WITH_WRAP=$(usex tcpd)"
)
}
src_compile() {
emake "${makeopts[@]}"
}
src_test() {
emake "${makeopts[@]}" test
}
src_install() {
emake "${makeopts[@]}" DESTDIR="${D}" prefix=/usr install
keepdir /var/lib/mosquitto
fowners mosquitto:mosquitto /var/lib/mosquitto
dodoc readme.md CONTRIBUTING.md ChangeLog.txt
doinitd "${FILESDIR}"/mosquitto
insinto /etc/mosquitto
doins mosquitto.conf
systemd_dounit "${FILESDIR}/mosquitto.service"
if use examples; then
docompress -x "/usr/share/doc/${PF}/examples"
insinto "/usr/share/doc/${PF}/examples"
doins -r examples/*
fi
}
pkg_postinst() {
elog ""
elog "The Python module has been moved out of mosquitto."
elog "See http://mosquitto.org/documentation/python/"
elog ""
elog "To start the mosquitto daemon at boot, add it to the default runlevel with:"
elog ""
elog " rc-update add mosquitto default"
elog " or"
elog " systemctl enable mosquitto"
}
|
GitWeb