blob: 3eb610321297745c934e6a55d43e8f00a75c6f45 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit multilib-minimal libtool
MY_P="gc-${PV}"
DESCRIPTION="The Boehm-Demers-Weiser conservative garbage collector"
HOMEPAGE="http://www.hboehm.info/gc/"
SRC_URI="http://www.hboehm.info/gc/gc_source/${MY_P}.tar.gz"
LICENSE="boehm-gc"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="cxx static-libs threads"
DEPEND="
>=dev-libs/libatomic_ops-7.4[${MULTILIB_USEDEP}]
virtual/pkgconfig"
S="${WORKDIR}/${MY_P}"
src_prepare() {
default
elibtoolize #594754
}
multilib_src_configure() {
local config=(
--with-libatomic-ops
$(use_enable cxx cplusplus)
$(use_enable static-libs static)
$(use threads || echo --disable-threads)
)
ECONF_SOURCE=${S} econf "${config[@]}"
}
multilib_src_install_all() {
local HTML_DOCS=( doc/*.html )
einstalldocs
dodoc doc/README{.environment,.linux,.macros}
rm -r "${ED%/}"/usr/share/gc || die
# package provides .pc files
find "${D}" -name '*.la' -delete || die
newman doc/gc.man GC_malloc.1
}
|
GitWeb
