blob: d053a69288eb38b807165c99e3e12beefe751016 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{5,6} )
inherit cmake-utils python-single-r1
MY_PN="libArcus"
DESCRIPTION="This library facilitates communication between Cura and its backend"
HOMEPAGE="https://github.com/Ultimaker/libArcus"
SRC_URI="https://github.com/Ultimaker/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="LGPL-3"
SLOT="0/3"
KEYWORDS="~amd64 ~x86"
IUSE="examples python static-libs"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
RDEPEND="${PYTHON_DEPS}
dev-python/sip[${PYTHON_USEDEP}]
dev-libs/protobuf
python? ( dev-python/protobuf-python[${PYTHON_USEDEP}] )"
DEPEND="${RDEPEND}"
S="${WORKDIR}/${MY_PN}-${PV}"
pkg_setup() {
use python && python-single-r1_pkg_setup
}
src_prepare() {
default
# Find SIP for current python version, not the latest installed
sed -i "s/find_package(Python3 3.4 REQUIRED/find_package(Python3 ${EPYTHON##python} EXACT REQUIRED/g" CMakeLists.txt || die
sed -i "s/find_package(Python3 3.4 REQUIRED/find_package(Python3 ${EPYTHON##python} EXACT REQUIRED/g" cmake/FindSIP.cmake || die
cmake-utils_src_prepare
}
src_configure() {
local mycmakeargs=(
-DBUILD_EXAMPLES=$(usex examples ON OFF)
-DBUILD_PYTHON=$(usex python ON OFF)
-DBUILD_STATIC=$(usex static-libs ON OFF)
)
cmake-utils_src_configure
}
|
GitWeb
