blob: 63f0e576f048b8339b73a87ce5799d1a3225a0b1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
inherit python-r1
MY_P=cfe-${PV/_/}.src
DESCRIPTION="Python bindings for sys-devel/clang"
HOMEPAGE="https://llvm.org/"
SRC_URI="https://releases.llvm.org/${PV}/${MY_P}.tar.xz"
S=${WORKDIR}/${MY_P}/bindings/python
LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-fbsd"
IUSE="test"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
RESTRICT="!test? ( test )"
# The module is opening libclang.so directly, and doing some blasphemy
# on top of it.
RDEPEND="
>=sys-devel/clang-${PV}:*
!sys-devel/llvm:0[clang(-),python(-)]
!sys-devel/clang:0[python(-)]
${PYTHON_DEPS}"
DEPEND="${RDEPEND}"
src_unpack() {
einfo "Unpacking parts of ${MY_P}.tar.xz ..."
tar -xJf "${DISTDIR}/${MY_P}.tar.xz" "${MY_P}/bindings/python" || die
}
python_test() {
"${EPYTHON}" -m unittest discover -v || die "Tests fail with ${EPYTHON}"
}
src_test() {
python_foreach_impl python_test
}
src_install() {
python_foreach_impl python_domodule clang
}
|
GitWeb
