blob: d35715a5eaa1dab6ac40709f38a42890d2dcc0e9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_FULLY_TESTED=( python3_{8..10} )
# networkx skips tests w/ missing deps and the available ones all pass w/ py3.11
PYTHON_COMPAT=( "${PYTHON_FULLY_TESTED[@]}" python3_11 )
inherit distutils-r1 optfeature virtualx
DESCRIPTION="Python tools to manipulate graphs and complex networks"
HOMEPAGE="
https://networkx.org/
https://github.com/networkx/networkx/
https://pypi.org/project/networkx/
"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
BDEPEND="
test? (
>=dev-python/lxml-4.5[${PYTHON_USEDEP}]
>=dev-python/pyyaml-3.13[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
>=dev-python/numpy-1.19[${PYTHON_USEDEP}]
>=dev-python/scipy-1.6.2[${PYTHON_USEDEP}]
' "${PYTHON_FULLY_TESTED[@]}")
)
"
distutils_enable_tests pytest
src_test() {
virtx distutils-r1_src_test
}
python_test() {
local EPYTEST_DESELECT=()
if ! has_version "dev-python/scipy[${PYTHON_USEDEP}]"; then
EPYTEST_DESELECT+=(
networkx/algorithms/tree/tests/test_mst.py::test_random_spanning_tree_additive_small
networkx/algorithms/tree/tests/test_mst.py::test_random_spanning_tree_multiplicative_small
)
fi
# virtx implies nonfatal
nonfatal epytest -p no:django || die
}
src_install() {
distutils-r1_src_install
# those examples use various assets and pre-compressed files
docompress -x /usr/share/doc/${PF}/examples
}
pkg_postinst() {
optfeature "recommended dependencies" "dev-python/matplotlib dev-python/numpy dev-python/pandas dev-python/scipy"
optfeature "graph drawing and graph layout algorithms" "dev-python/pygraphviz dev-python/pydot"
optfeature "YAML format reading and writing" "dev-python/pyyaml"
optfeature "shapefile format reading and writing" "dev-python/gdal"
optfeature "GraphML XML format" "dev-python/lxml"
}
|
GitWeb
