blob: e6169726869f471b8da88fe9f636172b35d6fdb8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
PYTHON_REQ_USE='tk?,threads(+)'
inherit distutils-r1 eutils virtualx
MY_PN=Pillow
MY_P=${MY_PN}-${PV}
DESCRIPTION="Python Imaging Library (fork)"
HOMEPAGE="https://python-pillow.org/"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
LICENSE="HPND"
SLOT="0"
KEYWORDS="amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc examples imagequant jpeg jpeg2k lcms test tiff tk truetype webp zlib"
REQUIRED_USE="test? ( jpeg tiff )"
RDEPEND="
dev-python/olefile[${PYTHON_USEDEP}]
imagequant? ( media-gfx/libimagequant:0 )
jpeg? ( virtual/jpeg:0 )
jpeg2k? ( media-libs/openjpeg:2= )
lcms? ( media-libs/lcms:2= )
tiff? ( media-libs/tiff:0=[jpeg,zlib] )
truetype? ( media-libs/freetype:2= )
webp? ( media-libs/libwebp:0= )
zlib? ( sys-libs/zlib:0= )"
DEPEND="${RDEPEND}
dev-python/setuptools[${PYTHON_USEDEP}]
doc? (
dev-python/sphinx[${PYTHON_USEDEP}]
dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
)
test? (
dev-python/nose[${PYTHON_USEDEP}]
media-gfx/imagemagick[png]
)
"
S="${WORKDIR}/${MY_P}"
PATCHES=(
"${FILESDIR}"/pillow-4.3.0-no-scripts.patch
# can be removed at v5, patch already uptream. See bug 593816.
"${FILESDIR}"/pillow-4.3.0-freetype2.9-test-metrics.patch
)
python_compile() {
# raqm not in portage yet
local args=(
--disable-raqm
--disable-platform-guessing
$(use_enable truetype freetype)
$(use_enable jpeg)
$(use_enable jpeg2k jpeg2000)
$(use_enable lcms)
$(use_enable tiff)
$(use_enable imagequant)
$(use_enable webp)
$(use_enable webp webpmux)
$(use_enable zlib)
)
distutils-r1_python_compile build_ext "${args[@]}"
}
python_compile_all() {
use doc && emake -C docs html
}
python_test() {
"${PYTHON}" selftest.py --installed || die "selftest failed with ${EPYTHON}"
virtx nosetests -vx Tests/test_*.py
}
python_install() {
python_doheader libImaging/*.h
distutils-r1_python_install
}
python_install_all() {
use doc && local HTML_DOCS=( docs/_build/html/. )
if use examples ; then
docinto examples
dodoc Scripts/*
docompress -x /usr/share/doc/${PF}/examples
fi
distutils-r1_python_install_all
}
|
GitWeb