blob: 4534586ab24993557a803feff54c83f0eed085aa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python{2_7,3_{5,6,7}} )
inherit cmake-utils git-r3 llvm multiprocessing python-single-r1 \
toolchain-funcs
DESCRIPTION="The LLVM debugger"
HOMEPAGE="https://llvm.org/"
SRC_URI=""
EGIT_REPO_URI="https://github.com/llvm/llvm-project.git"
S=${WORKDIR}/${P}/lldb
LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
SLOT="0"
KEYWORDS=""
IUSE="libedit lzma ncurses +python test"
REQUIRED_USE=${PYTHON_REQUIRED_USE}
RESTRICT="!test? ( test )"
RDEPEND="
libedit? ( dev-libs/libedit:0= )
lzma? ( app-arch/xz-utils:= )
ncurses? ( >=sys-libs/ncurses-5.9-r3:0= )
python? ( dev-python/six[${PYTHON_USEDEP}]
${PYTHON_DEPS} )
~sys-devel/clang-${PV}[xml]
~sys-devel/llvm-${PV}
!<sys-devel/llvm-4.0"
DEPEND="${RDEPEND}"
BDEPEND="
python? ( >=dev-lang/swig-3.0.11 )
test? (
~dev-python/lit-${PV}[${PYTHON_USEDEP}]
sys-devel/lld )
${PYTHON_DEPS}"
# least intrusive of all
CMAKE_BUILD_TYPE=RelWithDebInfo
pkg_setup() {
LLVM_MAX_SLOT=${PV%%.*} llvm_pkg_setup
python-single-r1_pkg_setup
}
src_unpack() {
local dirs=( lldb )
use test && dirs+=( llvm/lib/Testing/Support llvm/utils/unittest )
git-r3_fetch
git-r3_checkout '' '' '' "${dirs[@]}"
}
src_configure() {
local mycmakeargs=(
-DLLDB_DISABLE_CURSES=$(usex !ncurses)
-DLLDB_DISABLE_LIBEDIT=$(usex !libedit)
-DLLDB_DISABLE_PYTHON=$(usex !python)
-DLLDB_ENABLE_LZMA=$(usex lzma)
-DLLDB_USE_SYSTEM_SIX=1
-DLLVM_ENABLE_TERMINFO=$(usex ncurses)
-DLLDB_INCLUDE_TESTS=$(usex test)
-DCLANG_LINK_CLANG_DYLIB=ON
# TODO: fix upstream to detect this properly
-DHAVE_LIBDL=ON
-DHAVE_LIBPTHREAD=ON
# normally we'd have to set LLVM_ENABLE_TERMINFO, HAVE_TERMINFO
# and TERMINFO_LIBS... so just force FindCurses.cmake to use
# ncurses with complete library set (including autodetection
# of -ltinfo)
-DCURSES_NEED_NCURSES=ON
)
use test && mycmakeargs+=(
-DLLVM_BUILD_TESTS=$(usex test)
# compilers for lit tests
-DLLDB_TEST_C_COMPILER="$(type -P clang)"
-DLLDB_TEST_CXX_COMPILER="$(type -P clang++)"
-DLLVM_MAIN_SRC_DIR="${WORKDIR}/${P}/llvm"
-DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
-DLLVM_LIT_ARGS="-vv;-j;${LIT_JOBS:-$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")}"
)
cmake-utils_src_configure
}
src_test() {
local -x LIT_PRESERVES_TMP=1
cmake-utils_src_make check-lldb-lit
use python && cmake-utils_src_make check-lldb
}
src_install() {
cmake-utils_src_install
find "${D}" -name '*.a' -delete || die
use python && python_optimize
}
|
GitWeb