summaryrefslogtreecommitdiff
blob: 239b69e1ccb0c48d629e6f1e74b7e9bc1b34442b (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DESCRIPTION="Extensible editor for structured binary data"
HOMEPAGE="https://www.jemarch.net/poke"
SRC_URI="mirror://gnu/poke/${P}.tar.gz"

LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="machine-interface nls test"

RESTRICT="!test? ( test )"

# TODO: libnbd: not packaged in gentoo yet
# TODO: gui: does not seem to do anything :)
RDEPEND="
	dev-libs/boehm-gc:=
	dev-libs/libatomic_ops
	sys-devel/gettext
	sys-libs/readline:=
	machine-interface? ( dev-libs/json-c:= )
"
DEPEND="${RDEPEND}
	test? ( dev-util/dejagnu )"
BDEPEND="sys-devel/flex
	sys-devel/bison
	sys-apps/help2man
	virtual/pkgconfig"

src_configure() {
	econf \
		--disable-gui \
		--disable-libnbd \
		$(use_enable machine-interface mi) \
		$(use_enable nls)
}

src_install() {
	default

	find "${ED}" -name '*.la' -delete || die
}