blob: c62cda8abd5fe5fcabd25836e83513e95904f0ec (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
LUA_COMPAT=( lua5-1 )
inherit cmake lua-single xdg
DESCRIPTION="Portable Famicom/NES emulator, an evolution of the original FCE Ultra"
HOMEPAGE="https://fceux.com/"
SRC_URI="mirror://sourceforge/fceultra/${P}.src.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
REQUIRED_USE="${LUA_REQUIRED_USE}"
RDEPEND="
${LUA_DEPS}
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtopengl:5[-gles2-only]
dev-qt/qtwidgets:5
media-libs/libglvnd
media-libs/libsdl2[joystick,sound,threads,video]
sys-libs/zlib:=[minizip]"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
PATCHES=(
"${FILESDIR}"/${PN}-2.2.2-warnings.patch
)
DOCS=( README TODO-SDL changelog.txt documentation/. readme.md )
src_prepare() {
cmake_src_prepare
# remove hardcoded paths and deprecated options from .desktop
sed -e '/^Exec=/s:=.*/:=:' \
-e '/^Icon=/s:=.*:=fceux1:' \
-e '/^OnlyShowIn=/d' \
-i fceux.desktop || die
# avoid QA notice if no git, returns empty strings either way
sed -i '/^GIT_/s:=.*:=:' scripts/genGitHdr.sh || die
}
src_install() {
cmake_src_install
# remove unused/duplicate files
rm "${ED}"/usr/share/fceux/{lua5{1,.1}.dll,{fceux,taseditor}.chm} \
"${ED}"/usr/share/doc/${PF}/fceux{,-net-server}.6 \
"${ED}"/usr/share/man/man6/fceux-net-server.6 || die
}
|
GitWeb
