blob: 93e1bcf4e61a8a881f04b594790355c7642136e4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit cmake xdg-utils virtualx
DESCRIPTION="Tile-based, cross-platform 2D racing game"
HOMEPAGE="https://juzzlin.github.io/DustRacing2D/"
SRC_URI="https://github.com/juzzlin/DustRacing2D/archive/${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/DustRacing2D-${PV}"
LICENSE="GPL-3+ CC-BY-SA-3.0"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~x86"
IUSE="test"
RESTRICT="!test? ( test )"
RDEPEND="
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtopengl:5
dev-qt/qtxml:5
media-fonts/ubuntu-font-family
media-libs/libvorbis
media-libs/openal
virtual/opengl
"
DEPEND="${RDEPEND}
test? ( dev-qt/qttest:5 )
"
BDEPEND="
dev-qt/linguist-tools:5
virtual/pkgconfig
"
PATCHES=(
# upstream backports
"${FILESDIR}"/${P}-gcc10.patch # bug 722524
"${FILESDIR}"/${P}-opengl.patch
"${FILESDIR}"/${P}-appdata.patch
# downstream patches
"${FILESDIR}"/${P}-cmake.patch
"${FILESDIR}"/${P}-cmake-add_library-static.patch
)
src_configure() {
# -DGLES=ON didn't build for me but maybe just need use flags on some Qt package?
# Maybe add a local gles use flag
local mycmakeargs=(
-DReleaseBuild=ON
-DOpenGL_GL_PREFERENCE=GLVND
-DDATA_PATH=/usr/share/${PN}
-DBIN_PATH=/usr/bin
-DDOC_PATH=/usr/share/doc/${PF}
-DBUILD_TESTING=$(usex test)
)
cmake_src_configure
}
src_test() {
virtx cmake_src_test
}
src_install() {
cmake_src_install
dosym ../../fonts/ubuntu-font-family/UbuntuMono-B.ttf /usr/share/${PN}/fonts/UbuntuMono-B.ttf
dosym ../../fonts/ubuntu-font-family/UbuntuMono-R.ttf /usr/share/${PN}/fonts/UbuntuMono-R.ttf
}
pkg_postinst() {
xdg_icon_cache_update
}
pkg_postrm() {
xdg_icon_cache_update
}
|
GitWeb