blob: f668e9be0a116d1c242341bf0fe9f9ea76eece1e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools flag-o-matic multilib-minimal
DESCRIPTION="The Theora Video Compression Codec"
HOMEPAGE="https://www.theora.org"
SRC_URI="https://downloads.xiph.org/releases/theora/${P/_}.tar.bz2"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
IUSE="doc +encode examples static-libs"
REQUIRED_USE="examples? ( encode )" #285895
RDEPEND="
>=media-libs/libogg-1.3.0:=[${MULTILIB_USEDEP}]
encode? ( >=media-libs/libvorbis-1.3.3-r1:=[${MULTILIB_USEDEP}] )
examples? (
media-libs/libpng:0=
>=media-libs/libsdl-0.11.0
media-libs/libvorbis:=
)"
DEPEND="${RDEPEND}"
BDEPEND="
doc? ( app-doc/doxygen )
virtual/pkgconfig"
S=${WORKDIR}/${P/_}
VARTEXFONTS=${T}/fonts
DOCS=( AUTHORS CHANGES README )
PATCHES=(
"${FILESDIR}"/${PN}-1.0_beta2-flags.patch
"${FILESDIR}"/${P}-underlinking.patch
"${FILESDIR}"/${P}-libpng16.patch # bug 465450
"${FILESDIR}"/${P}-fix-UB.patch # bug 620800
)
src_prepare() {
default
# bug 467006
sed -i "s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/" configure.ac || die
AT_M4DIR=m4 eautoreconf
}
multilib_src_configure() {
use x86 && filter-flags -fforce-addr -frename-registers #200549
use doc || export ac_cv_prog_HAVE_DOXYGEN=false
local myconf=(
--disable-spec
$(use_enable encode)
$(use_enable static-libs static)
)
if [[ "${ABI}" = "${DEFAULT_ABI}" ]] ; then
myconf+=( $(use_enable examples) )
else
# those will be overwritten anyway
myconf+=( --disable-examples )
fi
# --disable-spec because LaTeX documentation has been prebuilt
ECONF_SOURCE="${S}" econf "${myconf[@]}"
}
multilib_src_install() {
emake \
DESTDIR="${D}" \
docdir="${EPREFIX}"/usr/share/doc/${PF} \
install
if use examples && [[ "${ABI}" = "${DEFAULT_ABI}" ]]; then
dobin examples/.libs/png2theora
for bin in dump_{psnr,video} {encoder,player}_example; do
newbin examples/.libs/${bin} theora_${bin}
done
fi
}
multilib_src_install_all() {
find "${D}" -name '*.la' -delete || die
einstalldocs
if use examples && use doc; then
docinto examples
dodoc examples/*.[ch]
docompress -x /usr/share/doc/${PF}/examples
docinto .
fi
}
|
GitWeb