1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=5
inherit cmake-utils multilib-minimal multilib multibuild flag-o-matic
if [[ ${PV} = 9999* ]]; then
inherit mercurial
EHG_REPO_URI="https://bitbucket.org/multicoreware/x265"
else
SRC_URI="
https://bitbucket.org/multicoreware/x265/downloads/${PN}_${PV}.tar.gz
http://ftp.videolan.org/pub/videolan/x265/${PN}_${PV}.tar.gz"
KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86"
fi
DESCRIPTION="Library for encoding video streams into the H.265/HEVC format"
HOMEPAGE="http://x265.org/"
LICENSE="GPL-2"
# subslot = libx265 soname
SLOT="0/110"
IUSE="+10bit +12bit neon numa pic power8 test"
ASM_DEPEND=">=dev-lang/yasm-1.2.0"
RDEPEND="numa? ( >=sys-process/numactl-2.0.10-r1[${MULTILIB_USEDEP}] )"
DEPEND="${RDEPEND}
abi_x86_32? ( ${ASM_DEPEND} )
abi_x86_64? ( ${ASM_DEPEND} )"
PATCHES=( "${FILESDIR}/arm.patch" "${FILESDIR}/neon.patch" "${FILESDIR}/ppc64.patch" )
src_unpack() {
if [[ ${PV} = 9999* ]]; then
mercurial_src_unpack
# Can't set it at global scope due to mercurial.eclass limitations...
export S=${WORKDIR}/${P}/source
else
unpack ${A}
export S="$(echo "${WORKDIR}/${PN}_"*"/source")"
fi
}
# By default, the library and the encoder is configured for only one output bit
# depth. Meaning, one has to rebuild libx265 if (s)he wants to produce HEVC
# files with a different bit depth, which is annoying. However, upstream
# supports proper namespacing for 8bits, 10bits & 12bits HEVC and linking all
# that together so that the resulting library can produce all three of them
# instead of only one.
# The API requires the bit depth parameter, so that libx265 can then chose which
# variant of the encoder to use.
# To achieve this, we have to build one (static) library for each non-main
# variant, and link it into the main library.
# Upstream documents using the 8bit variant as main library, hence we do not
# allow disabling it: "main" *MUST* come last in the following list.
x265_get_variants() {
local variants=""
use 12bit && variants+="main12 "
use 10bit && variants+="main10 "
variants+="main"
echo "${variants}"
}
x265_variant_src_configure() {
mkdir -p "${BUILD_DIR}" || die
pushd "${BUILD_DIR}" >/dev/null || die
local mycmakeargs=( "${myabicmakeargs[@]}" )
case "${MULTIBUILD_VARIANT}" in
"main12")
mycmakeargs+=(
-DHIGH_BIT_DEPTH=ON
-DEXPORT_C_API=OFF
-DENABLE_SHARED=OFF
-DENABLE_CLI=OFF
-DMAIN12=ON
)
if [[ ${ABI} = x86 ]] ; then
mycmakeargs+=( -DENABLE_ASSEMBLY=OFF )
fi
if [[ ${ABI} = arm ]] ; then
# 589674
mycmakeargs+=( -DENABLE_ASSEMBLY=OFF )
fi
if [[ ${ABI} = ppc64 ]] ; then
# https://bugs.gentoo.org/show_bug.cgi?id=607802#c5
mycmakeargs+=( -DENABLE_ASSEMBLY=OFF -DENABLE_ALTIVEC=OFF )
fi
;;
"main10")
mycmakeargs+=(
-DHIGH_BIT_DEPTH=ON
-DEXPORT_C_API=OFF
-DENABLE_SHARED=OFF
-DENABLE_CLI=OFF
)
if [[ ${ABI} = x86 ]] ; then
mycmakeargs+=( -DENABLE_ASSEMBLY=OFF )
fi
if [[ ${ABI} = arm ]] ; then
# 589674
mycmakeargs+=( -DENABLE_ASSEMBLY=OFF )
fi
if [[ ${ABI} = ppc64 ]] ; then
# https://bugs.gentoo.org/show_bug.cgi?id=607802#c5
mycmakeargs+=( -DENABLE_ASSEMBLY=OFF -DENABLE_ALTIVEC=OFF )
fi
;;
"main")
if (( "${#MULTIBUILD_VARIANTS[@]}" > 1 )) ; then
local myvariants=( "${MULTIBUILD_VARIANTS[@]}" )
unset myvariants[${#MULTIBUILD_VARIANTS[@]}-1]
local liblist=""
for v in "${myvariants[@]}" ; do
ln -s "${BUILD_DIR%-*}-${v}/libx265.a" "libx265_${v}.a" || die
liblist+="libx265_${v}.a;"
done
mycmakeargs+=(
-DEXTRA_LIB="${liblist}"
-DEXTRA_LINK_FLAGS=-L.
-DLINKED_10BIT=$(usex 10bit)
-DLINKED_12BIT=$(usex 12bit)
)
fi
;;
*)
die "Unknown variant: ${MULTIBUILD_VARIANT}";;
esac
cmake-utils_src_configure
popd >/dev/null || die
}
multilib_src_configure() {
append-cflags -fPIC
append-cxxflags -fPIC
local myabicmakeargs=(
$(cmake-utils_use_enable test TESTS)
$(multilib_is_native_abi || echo "-DENABLE_CLI=OFF")
-DENABLE_LIBNUMA=$(usex numa ON OFF)
-DCPU_POWER8=$(usex power8 ON OFF)
-DENABLE_ALTIVEC=$(usex power8 ON OFF)
-DLIB_INSTALL_DIR="$(get_libdir)"
)
if [[ ${ABI} = x86 ]] ; then
# Bug #528202
if use pic ; then
ewarn "PIC has been requested but x86 asm is not PIC-safe, disabling it."
myabicmakeargs+=( -DENABLE_ASSEMBLY=OFF )
fi
elif [[ ${ABI} = x32 ]] ; then
# bug #510890
myabicmakeargs+=( -DENABLE_ASSEMBLY=OFF )
elif [[ ${ABI} = arm ]] ; then
myabicmakeargs+=( -DENABLE_ASSEMBLY=$(usex pic OFF $(usex neon ON OFF)) )
use neon && use pic && ewarn "PIC has been requested but arm neon asm is not PIC-safe, disabling it."
fi
local MULTIBUILD_VARIANTS=( $(x265_get_variants) )
multibuild_foreach_variant x265_variant_src_configure
}
multilib_src_compile() {
local MULTIBUILD_VARIANTS=( $(x265_get_variants) )
multibuild_foreach_variant cmake-utils_src_compile
}
x265_variant_src_test() {
if [ -x "${BUILD_DIR}/test/TestBench" ] ; then
"${BUILD_DIR}/test/TestBench" || die
else
einfo "Unit tests check only assembly."
einfo "You do not seem to have any for ABI=${ABI}, x265 variant=${MULTIBUILD_VARIANT}"
einfo "Skipping tests."
fi
}
multilib_src_test() {
local MULTIBUILD_VARIANTS=( $(x265_get_variants) )
multibuild_foreach_variant x265_variant_src_test
}
multilib_src_install() {
# Install only "main" variant since the others are already linked into it.
local MULTIBUILD_VARIANTS=( "main" )
multibuild_foreach_variant cmake-utils_src_install
}
multilib_src_install_all() {
dodoc -r "${S}/../doc/"*
}
|
GitWeb