blob: fdc40118d3c16f38b7a2ae1e8e15c61f6e18fc58 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
EGO_PN="github.com/syncthing/syncthing"
EGIT_COMMIT=v${PV}
inherit golang-vcs-snapshot systemd user versionator
DESCRIPTION="Open Source Continuous File Synchronization"
HOMEPAGE="https://syncthing.net"
SRC_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
LICENSE="MPL-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~arm"
IUSE="tools"
DEPEND=""
RDEPEND=""
DOCS="README.md AUTHORS CONTRIBUTING.md"
pkg_setup() {
enewgroup ${PN}
enewuser ${PN} -1 -1 /var/lib/${PN} ${PN}
if use tools ; then
# separate user for relaysrv
enewgroup ${PN}-relaysrv
enewuser ${PN}-relaysrv -1 -1 /var/lib/${PN}-relaysrv ${PN}-relaysrv
fi
}
src_prepare() {
epatch "${FILESDIR}/relaysrv.systemd.patch"
eapply_user
}
src_compile() {
export GOPATH="${S}:$(get_golibdir_gopath)"
cd src/${EGO_PN}
# If we pass "build" to build.go, it builds only syncthing itself, and
# places the binary in the root folder. If we do not pass "build", all the
# tools are built, and all binaries are placed in folder ./bin.
ST_BUILD="build"
if use tools ; then
ST_BUILD=""
fi
go run build.go -version "v${PV}" -no-upgrade ${ST_BUILD} || die "build failed"
}
src_test() {
cd src/${EGO_PN}
go run build.go test || die "test failed"
}
src_install() {
cd src/${EGO_PN}
doman man/*.[157]
if use tools ; then
dobin bin/syncthing
exeinto /usr/libexec/syncthing
for exe in bin/* ; do
[ "${exe}" = "bin/syncthing" ] || doexe "${exe}"
done
else
dobin syncthing
fi
# openrc and systemd service files
systemd_dounit "${S}"/src/${EGO_PN}/etc/linux-systemd/system/${PN}@.service \
"${S}"/src/${EGO_PN}/etc/linux-systemd/system/${PN}-resume.service
systemd_douserunit "${S}"/src/${EGO_PN}/etc/linux-systemd/user/${PN}.service
newconfd "${FILESDIR}/${PN}.confd" ${PN}
newinitd "${FILESDIR}/${PN}.initd" ${PN}
keepdir /var/{lib,log}/${PN}
fowners ${PN}:${PN} /var/{lib,log}/${PN}
insinto /etc/logrotate.d
newins "${FILESDIR}/${PN}.logrotate" ${PN}
if use tools ; then
# openrc and systemd service files
systemd_dounit "${S}"/src/${EGO_PN}/cmd/relaysrv/etc/linux-systemd/${PN}-relaysrv.service
newconfd "${FILESDIR}/${PN}-relaysrv.confd" ${PN}-relaysrv
newinitd "${FILESDIR}/${PN}-relaysrv.initd" ${PN}-relaysrv
keepdir /var/lib/${PN}-relaysrv
fowners ${PN}-relaysrv:${PN}-relaysrv /var/{lib,log}/${PN}
insinto /etc/logrotate.d
newins "${FILESDIR}/syncthing-relaysrv.logrotate" syncthing-relaysrv
fi
}
pkg_postinst() {
if [[ $(get_version_component_range 2) -gt \
$(get_version_component_range 2 ${REPLACING_VERSIONS}) ]]; then
ewarn "Version ${PV} is not protocol-compatible with version" \
"0.$(($(get_version_component_range 2) - 1)).x or lower."
ewarn "Make sure all your devices are running at least version" \
"0.$(get_version_component_range 2).0."
fi
}
|
GitWeb