summaryrefslogtreecommitdiff
blob: da6218a96d9f4b5ccfda32e492dde97de6092910 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

DESCRIPTION="Library for reading and writing matlab files"
HOMEPAGE="https://sourceforge.net/projects/matio/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="BSD-2"
SLOT="0/9" # subslot = soname version
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc examples hdf5 sparse"

RDEPEND="
	sys-libs/zlib
	hdf5? ( sci-libs/hdf5:= )"
DEPEND="${RDEPEND}"
BDEPEND="doc? ( virtual/latex-base )"

src_configure() {
	econf \
		--disable-static \
		$(use_enable hdf5 mat73) \
		$(use_enable sparse extended-sparse)
}

src_compile() {
	default
	use doc && emake -C documentation pdf
}

src_install() {
	default
	use doc && dodoc documentation/matio_user_guide.pdf

	if use examples; then
		docinto examples
		dodoc test/test*.c
		insinto /usr/share/${PN}
		doins share/test*
	fi

	# no static archives
	find "${D}" -name "*.la" -delete || die
}