blob: 1d391a112ea3b9a2d04a81e0bfa304c099755b97 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI="6"
inherit toolchain-funcs flag-o-matic multilib autotools
MY_PN="${PN/-/_}"
MY_P="${MY_PN}-${PV}"
DESCRIPTION="Similar to dd but can copy from source with errors"
HOMEPAGE="http://www.garloff.de/kurt/linux/ddrescue/"
SRC_URI="http://www.garloff.de/kurt/linux/ddrescue/${MY_P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~mips ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
IUSE="cpu_flags_x86_avx2 lzo cpu_flags_x86_sse4_2 static xattr"
RDEPEND="lzo? ( dev-libs/lzo )
xattr? ( sys-apps/attr )"
DEPEND="${RDEPEND}"
S="${WORKDIR}/${MY_P}"
PATCHES=(
"${FILESDIR}"/${MY_PN}-1.99-musl-r1.patch
"${FILESDIR}"/${MY_PN}-1.99-disable-hmac-tests.patch
)
src_prepare() {
default
sed -i \
-e 's:-ldl:$(LDFLAGS) -ldl:' \
-e 's:-shared:$(CFLAGS) $(LDFLAGS) -shared:' \
Makefile || die
eautoreconf
}
src_configure() {
use static && append-ldflags -static
# OpenSSL is only used by a random helper tool we don't install.
ac_cv_header_attr_xattr_h=$(usex xattr) \
ac_cv_header_openssl_evp_h=no \
ac_cv_lib_crypto_EVP_aes_192_ctr=no \
ac_cv_lib_lzo2_lzo1x_1_compress=$(usex lzo) \
ac_cv_header_lzo_lzo1x_h=$(usex lzo) \
econf
}
_emake() {
local arch
case ${ARCH} in
x86) arch=i386;;
amd64) arch=x86_64;;
arm) arch=arm;;
arm64) arch=aarch64;;
esac
local os=$(usex kernel_linux Linux IDK)
# The Makefile is a mess. Override a few vars rather than patch it.
emake \
MACH="${arch}" \
OS="${os}" \
HAVE_SSE42=$(usex cpu_flags_x86_sse4_2 1 0) \
HAVE_AVX2=$(usex cpu_flags_x86_avx2 1 0) \
RPM_OPT_FLAGS="${CFLAGS} ${CPPFLAGS}" \
CFLAGS_OPT='$(CFLAGS)' \
LDFLAGS="${LDFLAGS} -Wl,-rpath,${EPREFIX%/}/usr/$(get_libdir)/${PN}" \
CC="$(tc-getCC)" \
"$@"
}
src_compile() {
_emake
}
src_test() {
_emake check
}
src_install() {
# easier to install by hand than trying to make sense of the Makefile.
dobin dd_rescue
dodir /usr/$(get_libdir)/${PN}
cp -pPR libddr_*.so "${ED%/}"/usr/$(get_libdir)/${PN}/ || die
dodoc README.dd_rescue
doman dd_rescue.1
use lzo && doman ddr_lzo.1
}
|
GitWeb