blob: 41c47a70a97f07a0843812cb7d796fdfaab52a87 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit flag-o-matic toolchain-funcs systemd usr-ldscript
DESCRIPTION="xfs filesystem utilities"
HOMEPAGE="https://xfs.wiki.kernel.org/"
SRC_URI="https://www.kernel.org/pub/linux/utils/fs/xfs/${PN}/${P}.tar.xz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="icu libedit nls readline"
LIB_DEPEND=">=sys-apps/util-linux-2.17.2[static-libs(+)]
icu? ( dev-libs/icu:=[static-libs(+)] )
readline? ( sys-libs/readline:0=[static-libs(+)] )
!readline? ( libedit? ( dev-libs/libedit[static-libs(+)] ) )"
RDEPEND="${LIB_DEPEND//\[static-libs(+)]}
!<sys-fs/xfsdump-3"
DEPEND="${RDEPEND}"
BDEPEND="
nls? ( sys-devel/gettext )
"
PATCHES=(
"${FILESDIR}"/${PN}-4.15.0-docdir.patch
"${FILESDIR}"/${PN}-5.3.0-libdir.patch
)
pkg_setup() {
if use readline && use libedit ; then
ewarn "You have USE='readline libedit' but these are exclusive."
ewarn "Defaulting to readline; please disable this USE flag if you want libedit."
fi
}
src_prepare() {
default
# Fix doc dir
sed -i \
-e "/^PKG_DOC_DIR/s:@pkg_name@:${PF}:" \
include/builddefs.in || die
# Don't install compressed docs
sed 's@\(CHANGES\)\.gz[[:space:]]@\1 @' -i doc/Makefile || die
}
src_configure() {
# include/builddefs.in will add FCFLAGS to CFLAGS which will
# unnecessarily clutter CFLAGS (and fortran isn't used)
unset FCFLAGS
export DEBUG=-DNDEBUG
# Package is honoring CFLAGS; No need to use OPTIMIZER anymore.
# However, we have to provide an empty value to avoid default
# flags.
export OPTIMIZER=" "
unset PLATFORM # if set in user env, this breaks configure
# Avoid automagic on libdevmapper, #709694
export ac_cv_search_dm_task_create=no
# Upstream does NOT support --disable-static anymore,
# https://www.spinics.net/lists/linux-xfs/msg30185.html
# https://www.spinics.net/lists/linux-xfs/msg30272.html
local myconf=(
--enable-blkid
--with-crond-dir="${EPREFIX}/etc/cron.d"
--with-systemd-unit-dir="$(systemd_get_systemunitdir)"
$(use_enable icu libicu)
$(use_enable nls gettext)
$(use_enable readline)
$(usex readline --disable-editline $(use_enable libedit editline))
)
if is-flagq -fno-lto ; then
einfo "LTO disabled via {C,CXX,F,FC}FLAGS"
myconf+=( --disable-lto )
else
if is-flagq -flto ; then
einfo "LTO forced via {C,CXX,F,FC}FLAGS"
myconf+=( --enable-lto )
elif use amd64 || use x86 ; then
# match upstream default
myconf+=( --enable-lto )
else
# LTO can cause problems on some architectures, bug 655638
myconf+=( --disable-lto )
fi
fi
econf "${myconf[@]}"
}
src_compile() {
emake V=1
}
src_install() {
emake DIST_ROOT="${ED}" install
emake DIST_ROOT="${ED}" install-dev
gen_usr_ldscript -a handle
}
|
GitWeb