blob: 312ab570210b296ad9992b0aa51128d4d26823cc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit autotools toolchain-funcs multilib-minimal
DESCRIPTION="Utilities and libraries for NUMA systems"
HOMEPAGE="https://github.com/numactl/numactl"
if [[ "${PV}" == 9999 ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/numactl/numactl.git"
else
SRC_URI="https://github.com/numactl/numactl/releases/download/v${PV}/${P}.tar.gz"
# ARM lacks the __NR_migrate_pages syscall.
KEYWORDS="~amd64 -arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~x86 ~amd64-linux"
fi
LICENSE="GPL-2"
SLOT="0"
IUSE="static-libs"
PATCHES=(
"${FILESDIR}"/${PN}-2.0.10-numademo-cflags.patch #540856
)
src_prepare() {
default
eautoreconf
# We need to copy the sources or else tests will fail
multilib_copy_sources
}
multilib_src_configure() {
ECONF_SOURCE="${S}" econf $(use_enable static-libs static)
}
multilib_src_compile() {
multilib_is_native_abi && default || emake libnuma.la
}
multilib_src_test() {
if multilib_is_native_abi ; then
if [ -d /sys/devices/system/node ]; then
einfo "The only generically safe test is regress2."
einfo "The other test cases require 2 NUMA nodes."
emake regress2
else
ewarn "You do not have baseline NUMA support in your kernel, skipping tests."
fi
fi
}
multilib_src_install() {
emake DESTDIR="${D}" \
install$(multilib_is_native_abi || echo "-libLTLIBRARIES install-includeHEADERS")
find "${ED%/}"/usr/ -name libnuma.la -delete || die
}
multilib_src_install_all() {
local DOCS=( README.md )
einstalldocs
# delete man pages provided by the man-pages package #238805
rm -r "${ED%/}"/usr/share/man/man[25] || die
}
|
GitWeb
