blob: 309f0c09793935464559a82bc0c2f6d891e62c8c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
XORG_DOC=doc
XORG_TARBALL_SUFFIX="xz"
inherit xorg-3 meson
EGIT_REPO_URI="https://gitlab.freedesktop.org/xorg/xserver.git"
XORG_EAUTORECONF="no"
DESCRIPTION="X.Org X servers"
SLOT="0/${PV}"
if [[ ${PV} != 9999* ]]; then
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
fi
IUSE_SERVERS="xephyr xnest xorg xvfb"
IUSE="${IUSE_SERVERS} debug +elogind minimal selinux suid systemd test +udev unwind xcsecurity"
RESTRICT="!test? ( test )"
CDEPEND="
media-libs/libglvnd[X]
dev-libs/openssl:0=
>=x11-apps/iceauth-1.0.2
>=x11-apps/rgb-1.0.3
>=x11-apps/xauth-1.0.3
x11-apps/xkbcomp
>=x11-libs/libdrm-2.4.89
>=x11-libs/libpciaccess-0.12.901
>=x11-libs/libXau-1.0.4
>=x11-libs/libXdmcp-1.0.2
>=x11-libs/libXfont2-2.0.1
>=x11-libs/libxcvt-0.1.0
>=x11-libs/libxkbfile-1.0.4
>=x11-libs/libxshmfence-1.1
>=x11-libs/pixman-0.27.2
>=x11-misc/xbitmaps-1.0.1
>=x11-misc/xkeyboard-config-2.4.1-r3
>=x11-libs/libXext-1.0.5
x11-libs/libXv
xephyr? (
x11-libs/libxcb[xkb]
x11-libs/xcb-util
x11-libs/xcb-util-image
x11-libs/xcb-util-keysyms
x11-libs/xcb-util-renderutil
x11-libs/xcb-util-wm
)
!minimal? (
>=x11-libs/libX11-1.1.5
>=x11-libs/libXext-1.0.5
>=media-libs/mesa-18[X(+),egl(+),gbm(+)]
>=media-libs/libepoxy-1.5.4[X,egl(+)]
)
udev? ( virtual/libudev:= )
unwind? ( sys-libs/libunwind )
>=x11-apps/xinit-1.3.3-r1
systemd? (
sys-apps/dbus
sys-apps/systemd
)
elogind? (
sys-apps/dbus
sys-auth/elogind[pam]
sys-auth/pambase[elogind]
)
!!x11-drivers/nvidia-drivers[-libglvnd(+)]
"
DEPEND="${CDEPEND}
>=x11-base/xorg-proto-2021.4.99.2
>=x11-libs/xtrans-1.3.5
"
RDEPEND="${CDEPEND}
!systemd? ( gui-libs/display-manager-init )
selinux? ( sec-policy/selinux-xserver )
"
BDEPEND="
sys-devel/flex
"
PDEPEND="
xorg? ( >=x11-base/xorg-drivers-$(ver_cut 1-2) )"
REQUIRED_USE="!minimal? (
|| ( ${IUSE_SERVERS} )
)
elogind? ( udev )
?? ( elogind systemd )"
UPSTREAMED_PATCHES=(
)
PATCHES=(
"${UPSTREAMED_PATCHES[@]}"
"${FILESDIR}"/${PN}-1.12-unloadsubmodule.patch
# needed for new eselect-opengl, bug #541232
"${FILESDIR}"/${PN}-1.18-support-multiple-Files-sections.patch
)
src_configure() {
# localstatedir is used for the log location; we need to override the default
# from ebuild.sh
# sysconfdir is used for the xorg.conf location; same applies
# NOTE: fop is used for doc generating; and I have no idea if Gentoo
# package it somewhere
local emesonargs=(
--localstatedir "${EPREFIX}/var"
--sysconfdir "${EPREFIX}/etc/X11"
--buildtype $(usex debug debug plain)
-Db_ndebug=$(usex debug false true)
$(meson_use doc docs)
$(meson_use !minimal dri1)
$(meson_use !minimal dri2)
$(meson_use !minimal dri3)
$(meson_use !minimal glamor)
$(meson_use !minimal glx)
$(meson_use udev)
$(meson_use udev udev_kms)
$(meson_use unwind libunwind)
$(meson_use xcsecurity)
$(meson_use xephyr)
$(meson_use xnest)
$(meson_use xorg)
$(meson_use xvfb)
-Ddefault_font_path="${EPREFIX}"/usr/share/fonts
-Ddrm=true
-Ddtrace=false
-Dipv6=true
-Dhal=false
-Dlinux_acpi=false
-Dsha1=libcrypto
-Dxkb_output_dir="${EPREFIX}/var/lib/xkb"
-Dxwayland=false
)
if use systemd || use elogind; then
emesonargs+=(
-Dsystemd_logind=true
$(meson_use suid suid_wrapper)
)
else
emesonargs+=(
-Dsystemd_logind=false
$(meson_use suid suid_wrapper)
)
fi
meson_src_configure
}
src_install() {
meson_src_install
#The new meson build system do not leave X symlink
ln -s Xorg "${ED}"/usr/bin/X
if ! use xorg; then
rm -f "${ED}"/usr/share/man/man1/Xserver.1x \
"${ED}"/usr/$(get_libdir)/xserver/SecurityPolicy \
"${ED}"/usr/$(get_libdir)/pkgconfig/xorg-server.pc \
"${ED}"/usr/share/man/man1/Xserver.1x || die
fi
# install the @x11-module-rebuild set for Portage
insinto /usr/share/portage/config/sets
newins "${FILESDIR}"/xorg-sets.conf xorg.conf
}
pkg_postrm() {
# Get rid of module dir to ensure opengl-update works properly
if [[ -z ${REPLACED_BY_VERSION} && -e ${EROOT}/usr/$(get_libdir)/xorg/modules ]]; then
rm -rf "${EROOT}"/usr/$(get_libdir)/xorg/modules
fi
}
|
GitWeb