Sync from portage tree. Remove experimental ebuild linking to Xaw3dxft.

svn path=/emacs-overlay/; revision=1637

5 files changed, 13 insertions, 351 deletions

diff --git a/app-editors/emacs-vcs/ChangeLog b/app-editors/emacs-vcs/ChangeLog
index 6fd507c..dd2f754 100644
--- a/app-editors/emacs-vcs/ChangeLog
+++ b/app-editors/emacs-vcs/ChangeLog
@@ -2,6 +2,10 @@
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
 # $Header: $
 
+  19 Mar 2011; Ulrich Mueller <ulm@gentoo.org> emacs-vcs-23.3.9999.ebuild,
+  emacs-vcs-24.0.9999-r1.ebuild, -emacs-vcs-24.0.9999-r2.ebuild:
+  Sync from portage tree. Remove experimental ebuild linking to Xaw3dxft.
+
   11 Mar 2011; Ulrich Mueller <ulm@gentoo.org> emacs-vcs-23.3.9999.ebuild:
   Sync from portage tree.
 
diff --git a/app-editors/emacs-vcs/Manifest b/app-editors/emacs-vcs/Manifest
index 5f1b0d7..ae8cf97 100644
--- a/app-editors/emacs-vcs/Manifest
+++ b/app-editors/emacs-vcs/Manifest
@@ -1,15 +1,14 @@
 -----BEGIN PGP SIGNED MESSAGE-----
 Hash: SHA1
 
-EBUILD emacs-vcs-23.3.9999.ebuild 10479 RMD160 d8d6039df9cc8474d6f9a07db58ca36d663ddd23 SHA1 4e2428c8906ade6d5d0a6a3cdf51b2a3e734caef SHA256 7905fdae21c51ffcf7f5dc6984e6d82fbad7161299078a26ccb63afdcc0c6d0a
-EBUILD emacs-vcs-24.0.9999-r1.ebuild 10586 RMD160 272e292b8bd8caecc0600eb4eaa15f1196418f1f SHA1 f8662ebfa6f37abc4606b010819cfc8f42ec1989 SHA256 b115cede392560400b906232f8369546254b295b0f6b63af722394525b47df79
-EBUILD emacs-vcs-24.0.9999-r2.ebuild 10612 RMD160 7fd5a1385108d03be8c8cb026aac2ccd2962293a SHA1 fe12395374f016c3e39457b391111e3a2cab3cac SHA256 2e879bcb52cbef733d34518e2e7e31bb169beffb03a61bb01c26ba851a7d2f87
-MISC ChangeLog 2822 RMD160 59714ff2133f3839cd24360506840e7265a77f3c SHA1 b9357e60c09698fafc8ae32d3ce928144524eb70 SHA256 2e4f76146bb9d58370e8de2b72cde939ad1445c7b503cbc0c40be77ba97475d1
+EBUILD emacs-vcs-23.3.9999.ebuild 10439 RMD160 97bc213e09f3d3ab36bb2b75f0a87a95db835976 SHA1 9f99a71de87e7da5be80207593ac6fbd79581f30 SHA256 c11a8e1807c04fd48de8bd20b77d682e708a29a8e3cee7af8657ad8223381c04
+EBUILD emacs-vcs-24.0.9999-r1.ebuild 10524 RMD160 7d614f0cfcf4a93f74fd0e666c6c5d7a8d62c751 SHA1 1b7871039ad22b4492be3373e6b53bbb21a97d0f SHA256 d0bd27b50cb5e89c8deff8546ee9ed03d30514e81e1bf0cf314b42e45a60c979
+MISC ChangeLog 3037 RMD160 df670e4421affad28c389b1f8c73188898b35c20 SHA1 c350388f640fc8f89990b35313dcdcfce35f3a4e SHA256 7bab5a0ac1caacc4c2465a00058c01e4c19a7d771a010f9c7a1197d8584a6df1
 MISC metadata.xml 1801 RMD160 606c780a3e86f485699157f14a35ca0e5da1d3c2 SHA1 05839ee25c6f6389e8eb80d783df895d59600a90 SHA256 bdc233a1795f52900dbe4d0a39c0e56d4eb5ba1c4842b9c46bae47f7052d5d74
 -----BEGIN PGP SIGNATURE-----
 Version: GnuPG v2.0.17 (GNU/Linux)
 
-iEYEARECAAYFAk17bdQACgkQOeoy/oIi7uyxYACeLX4ihllZg0QkY9oryaxhf5vh
-RkAAmQFHnHn3FD07e8U/yUyMaDJ6MyLE
-=q61z
+iEYEARECAAYFAk2EeaUACgkQOeoy/oIi7uxrYgCeJeDd/ZPTpJ9aIGl+DqNpuSqW
+JFAAoMyd1p0VE+dWIqyKh70sGCtY2lFL
+=kD9t
 -----END PGP SIGNATURE-----
diff --git a/app-editors/emacs-vcs/emacs-vcs-23.3.9999.ebuild b/app-editors/emacs-vcs/emacs-vcs-23.3.9999.ebuild
index 53d56cd..aa0518b 100644
--- a/app-editors/emacs-vcs/emacs-vcs-23.3.9999.ebuild
+++ b/app-editors/emacs-vcs/emacs-vcs-23.3.9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/emacs-vcs/emacs-vcs-23.3.9999.ebuild,v 1.5 2011/03/12 12:56:11 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/emacs-vcs/emacs-vcs-23.3.9999.ebuild,v 1.6 2011/03/19 09:34:59 ulm Exp $
 
 EAPI=4
 WANT_AUTOMAKE="none"
@@ -126,7 +126,7 @@ src_prepare() {
 src_configure() {
 	ALLOWED_FLAGS=""
 	strip-flags
-	filter-flags -fstack-protector -fstack-protector-all -fstrict-aliasing
+	filter-flags -fstrict-aliasing
 	append-flags $(test-flags -fno-strict-aliasing)
 
 	if use sh; then
diff --git a/app-editors/emacs-vcs/emacs-vcs-24.0.9999-r1.ebuild b/app-editors/emacs-vcs/emacs-vcs-24.0.9999-r1.ebuild
index 3c58fb0..3f64331 100644
--- a/app-editors/emacs-vcs/emacs-vcs-24.0.9999-r1.ebuild
+++ b/app-editors/emacs-vcs/emacs-vcs-24.0.9999-r1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/emacs-vcs/emacs-vcs-24.0.9999-r1.ebuild,v 1.4 2011/02/02 19:29:05 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/emacs-vcs/emacs-vcs-24.0.9999-r1.ebuild,v 1.9 2011/03/19 09:34:59 ulm Exp $
 
 EAPI=4
 
@@ -124,7 +124,6 @@ src_prepare() {
 src_configure() {
 	ALLOWED_FLAGS=""
 	strip-flags
-	filter-flags -fstack-protector -fstack-protector-all	#285778
 
 	if use sh; then
 		replace-flags -O[1-9] -O0		#262359
diff --git a/app-editors/emacs-vcs/emacs-vcs-24.0.9999-r2.ebuild b/app-editors/emacs-vcs/emacs-vcs-24.0.9999-r2.ebuild
deleted file mode 100644
index 5f24746..0000000
--- a/app-editors/emacs-vcs/emacs-vcs-24.0.9999-r2.ebuild
+++ /dev/null
@@ -1,340 +0,0 @@
-# Copyright 1999-2011 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/emacs-vcs/emacs-vcs-24.0.9999-r1.ebuild,v 1.4 2011/02/02 19:29:05 ulm Exp $
-
-EAPI=4
-
-inherit autotools elisp-common eutils flag-o-matic multilib
-
-if [ "${PV##*.}" = "9999" ]; then
-	EBZR_PROJECT="emacs"
-	EBZR_BRANCH="trunk"
-	EBZR_REPO_URI="bzr://bzr.savannah.gnu.org/emacs/${EBZR_BRANCH}/"
-	# "Nosmart" is much faster for initial branching.
-	EBZR_INITIAL_URI="nosmart+${EBZR_REPO_URI}"
-	inherit bzr
-	SRC_URI=""
-else
-	SRC_URI="mirror://gentoo/emacs-${PV}.tar.gz
-		ftp://alpha.gnu.org/gnu/emacs/pretest/emacs-${PV}.tar.gz"
-	# FULL_VERSION keeps the full version number, which is needed in
-	# order to determine some path information correctly for copy/move
-	# operations later on
-	FULL_VERSION="${PV%%_*}"
-	S="${WORKDIR}/emacs-${FULL_VERSION}"
-fi
-
-DESCRIPTION="The extensible, customizable, self-documenting real-time display editor"
-HOMEPAGE="http://www.gnu.org/software/emacs/"
-
-LICENSE="GPL-3 FDL-1.3 BSD as-is MIT W3C unicode"
-SLOT="24"
-KEYWORDS=""
-IUSE="alsa dbus gconf gif gnutls gpm gtk gzip-el hesiod imagemagick jpeg kerberos libxml2 m17n-lib motif png selinux sound source svg tiff toolkit-scroll-bars X Xaw3d xft +xpm"
-RESTRICT="strip"
-
-RDEPEND="sys-libs/ncurses
-	>=app-admin/eselect-emacs-1.2
-	net-libs/liblockfile
-	hesiod? ( net-dns/hesiod )
-	kerberos? ( virtual/krb5 )
-	alsa? ( media-libs/alsa-lib )
-	gpm? ( sys-libs/gpm )
-	dbus? ( sys-apps/dbus )
-	gnutls? ( net-libs/gnutls )
-	selinux? ( sys-libs/libselinux )
-	X? (
-		x11-libs/libXmu
-		x11-libs/libXt
-		x11-misc/xbitmaps
-		gconf? ( >=gnome-base/gconf-2.26.2 )
-		libxml2? ( >=dev-libs/libxml2-2.2.0 )
-		gif? ( media-libs/giflib )
-		jpeg? ( virtual/jpeg )
-		png? ( media-libs/libpng )
-		svg? ( >=gnome-base/librsvg-2.0 )
-		tiff? ( media-libs/tiff )
-		xpm? ( x11-libs/libXpm )
-		imagemagick? ( >=media-gfx/imagemagick-6.6.2 )
-		xft? (
-			media-libs/fontconfig
-			media-libs/freetype
-			x11-libs/libXft
-			m17n-lib? (
-				>=dev-libs/libotf-0.9.4
-				>=dev-libs/m17n-lib-1.5.1
-			)
-		)
-		gtk? ( x11-libs/gtk+:2 )
-		!gtk? (
-			Xaw3d? ( x11-libs/Xaw3dxft )
-			!Xaw3d? ( motif? ( >=x11-libs/openmotif-2.3:0 ) )
-		)
-	)"
-
-DEPEND="${RDEPEND}
-	dev-util/pkgconfig
-	gzip-el? ( app-arch/gzip )"
-
-RDEPEND="${RDEPEND}
-	>=app-emacs/emacs-common-gentoo-1[X?]"
-
-EMACS_SUFFIX="emacs-${SLOT}"
-SITEFILE="20${PN}-${SLOT}-gentoo.el"
-
-pkg_setup() {
-	local olddir="${EBZR_STORE_DIR}/emacs-${EBZR_BRANCH#emacs-}"
-	if [ -d "${olddir}" ]; then
-		ewarn "bzr.eclass uses branches instead of checkouts now."
-		ewarn "Therefore, you may remove the old bzr checkout:"
-		ewarn "rm -rf ${olddir}"
-	fi
-}
-
-src_prepare() {
-	if [ "${PV##*.}" = "9999" ]; then
-		FULL_VERSION=$(sed -n 's/^AC_INIT(emacs,[ \t]*\([^ \t,)]*\).*/\1/p' \
-			configure.in)
-		[ "${FULL_VERSION}" ] || die "Cannot determine current Emacs version"
-		echo
-		einfo "Emacs branch: ${EBZR_BRANCH}"
-		einfo "Emacs version number: ${FULL_VERSION}"
-		[[ ${FULL_VERSION} =~ ^${PV%.*}(\..*)?$ ]] \
-			|| die "Upstream version number changed to ${FULL_VERSION}"
-		echo
-	fi
-
-	sed -i -e 's:X11/Xaw3d:&xft:' configure.in src/*.c lwlib/*.c || die
-	sed -i -e '/AC_CHECK_LIB\|LUCID_LIBW/s:Xaw3d:&xft:' configure.in || die
-
-	if ! use alsa; then
-		# ALSA is detected even if not requested by its USE flag.
-		# Suppress it by supplying pkg-config with a wrong library name.
-		sed -i -e "/ALSA_MODULES=/s/alsa/DiSaBlEaLsA/" configure.in \
-			|| die "unable to sed configure.in"
-	fi
-	if ! use gzip-el; then
-		# Emacs' build system automatically detects the gzip binary and
-		# compresses el files. We don't want that so confuse it with a
-		# wrong binary name
-		sed -i -e "s/ gzip/ PrEvEnTcOmPrEsSiOn/" configure.in \
-			|| die "unable to sed configure.in"
-	fi
-
-	AT_M4DIR=m4 eautoreconf
-}
-
-src_configure() {
-	ALLOWED_FLAGS=""
-	strip-flags
-	filter-flags -fstack-protector -fstack-protector-all	#285778
-
-	if use sh; then
-		replace-flags -O[1-9] -O0		#262359
-	elif use ia64; then
-		replace-flags -O[2-9] -O1		#325373
-	else
-		replace-flags -O[3-9] -O2
-	fi
-
-	local myconf
-
-	if use alsa && ! use sound; then
-		echo
-		einfo "Although sound USE flag is disabled you chose to have alsa,"
-		einfo "so sound is switched on anyway."
-		echo
-		myconf="${myconf} --with-sound"
-	else
-		myconf="${myconf} $(use_with sound)"
-	fi
-
-	if use X; then
-		myconf="${myconf} --with-x"
-		myconf="${myconf} $(use_with gconf) $(use_with libxml2 xml2)"
-		myconf="${myconf} $(use_with toolkit-scroll-bars)"
-		myconf="${myconf} $(use_with gif) $(use_with jpeg)"
-		myconf="${myconf} $(use_with png) $(use_with svg rsvg)"
-		myconf="${myconf} $(use_with tiff) $(use_with xpm)"
-		myconf="${myconf} $(use_with imagemagick) $(use_with xft)"
-
-		if use xft; then
-			myconf="${myconf} $(use_with m17n-lib libotf)"
-			myconf="${myconf} $(use_with m17n-lib m17n-flt)"
-		else
-			myconf="${myconf} --without-libotf --without-m17n-flt"
-			use m17n-lib && ewarn \
-				"USE flag \"m17n-lib\" has no effect because xft is not set."
-		fi
-
-		# GTK+ is the default toolkit if USE=gtk is chosen with other
-		# possibilities. Emacs upstream thinks this should be standard
-		# policy on all distributions
-		if use gtk; then
-			einfo "Configuring to build with GIMP Toolkit (GTK+)"
-			myconf="${myconf} --with-x-toolkit=gtk"
-		elif use Xaw3d; then
-			einfo "Configuring to build with Xaw3d (Athena/Lucid) toolkit"
-			myconf="${myconf} --with-x-toolkit=athena"
-		elif use motif; then
-			einfo "Configuring to build with Motif toolkit"
-			myconf="${myconf} --with-x-toolkit=motif"
-		else
-			einfo "Configuring to build with no toolkit"
-			myconf="${myconf} --with-x-toolkit=no"
-		fi
-
-		local f tk=
-		for f in gtk Xaw3d motif; do
-			use ${f} || continue
-			[ "${tk}" ] \
-				&& ewarn "USE flag \"${f}\" ignored (superseded by \"${tk}\")"
-			tk="${tk}${tk:+ }${f}"
-		done
-	else
-		myconf="${myconf} --without-x"
-	fi
-
-	# According to configure, this option is only used for GNU/Linux
-	# (x86_64 and s390). For Gentoo Prefix we have to explicitly spell
-	# out the location because $(get_libdir) does not necessarily return
-	# something that matches the host OS's libdir naming (e.g. RHEL).
-	local crtdir=$($(tc-getCC) -print-file-name=crt1.o)
-	crtdir=${crtdir%/*}
-
-	econf \
-		--program-suffix=-${EMACS_SUFFIX} \
-		--infodir="${EPREFIX}"/usr/share/info/${EMACS_SUFFIX} \
-		--with-crt-dir="${crtdir}" \
-		--with-gameuser="${GAMES_USER_DED:-games}" \
-		--without-compress-info \
-		$(use_with hesiod) \
-		$(use_with kerberos) $(use_with kerberos kerberos5) \
-		$(use_with gpm) \
-		$(use_with dbus) \
-		$(use_with gnutls) \
-		$(use_with selinux) \
-		${myconf}
-}
-
-src_compile() {
-	export SANDBOX_ON=0			# for the unbelievers, see Bug #131505
-	if [ "${PV##*.}" = "9999" ]; then
-		emake CC="$(tc-getCC)" bootstrap
-		# cleanup, otherwise emacs will be dumped again in src_install
-		(cd src; emake versionclean)
-	fi
-	emake CC="$(tc-getCC)"
-}
-
-src_install () {
-	local i m
-
-	emake install DESTDIR="${D}"
-
-	rm "${ED}"/usr/bin/emacs-${FULL_VERSION}-${EMACS_SUFFIX} \
-		|| die "removing duplicate emacs executable failed"
-	mv "${ED}"/usr/bin/emacs-${EMACS_SUFFIX} "${ED}"/usr/bin/${EMACS_SUFFIX} \
-		|| die "moving Emacs executable failed"
-
-	# move man pages to the correct place
-	for m in "${ED}"/usr/share/man/man1/* ; do
-		mv "${m}" "${m%.1}-${EMACS_SUFFIX}.1" || die "mv man failed"
-	done
-
-	# move info dir to avoid collisions with the dir file generated by portage
-	mv "${ED}"/usr/share/info/${EMACS_SUFFIX}/dir{,.orig} \
-		|| die "moving info dir failed"
-	touch "${ED}"/usr/share/info/${EMACS_SUFFIX}/.keepinfodir
-	docompress -x /usr/share/info/${EMACS_SUFFIX}/dir.orig
-
-	# avoid collision between slots, see bug #169033 e.g.
-	rm "${ED}"/usr/share/emacs/site-lisp/subdirs.el
-	rm -rf "${ED}"/usr/share/{applications,icons}
-	rm "${ED}"/var/lib/games/emacs/{snake,tetris}-scores
-	keepdir /var/lib/games/emacs
-
-	local c=";;"
-	if use source; then
-		insinto /usr/share/emacs/${FULL_VERSION}/src
-		# This is not meant to install all the source -- just the
-		# C source you might find via find-function
-		doins src/*.[ch]
-		c=""
-	fi
-
-	sed 's/^X//' >"${T}/${SITEFILE}" <<-EOF
-	X
-	;;; ${PN}-${SLOT} site-lisp configuration
-	X
-	(when (string-match "\\\\\`${FULL_VERSION//./\\\\.}\\\\>" emacs-version)
-	X  ${c}(setq find-function-C-source-directory
-	X  ${c}      "${EPREFIX}/usr/share/emacs/${FULL_VERSION}/src")
-	X  (let ((path (getenv "INFOPATH"))
-	X	(dir "${EPREFIX}/usr/share/info/${EMACS_SUFFIX}")
-	X	(re "\\\\\`${EPREFIX}/usr/share/info\\\\>"))
-	X    (and path
-	X	 ;; move Emacs Info dir before anything else in /usr/share/info
-	X	 (let* ((p (cons nil (split-string path ":" t))) (q p))
-	X	   (while (and (cdr q) (not (string-match re (cadr q))))
-	X	     (setq q (cdr q)))
-	X	   (setcdr q (cons dir (delete dir (cdr q))))
-	X	   (setq Info-directory-list (prune-directory-list (cdr p)))))))
-	EOF
-	elisp-site-file-install "${T}/${SITEFILE}" || die
-
-	dodoc README BUGS
-}
-
-pkg_preinst() {
-	# move Info dir file to correct name
-	local infodir=/usr/share/info/${EMACS_SUFFIX} f
-	if [ -f "${ED}"${infodir}/dir.orig ]; then
-		mv "${ED}"${infodir}/dir{.orig,} || die "moving info dir failed"
-	else
-		# this should not happen in EAPI 4
-		ewarn "Regenerating Info directory index in ${infodir} ..."
-		rm -f "${ED}"${infodir}/dir{,.*}
-		for f in "${ED}"${infodir}/*; do
-			if [[ ${f##*/} != *-[0-9]* && -e ${f} ]]; then
-				install-info --info-dir="${ED}"${infodir} "${f}" \
-					|| die "install-info failed"
-			fi
-		done
-	fi
-}
-
-pkg_postinst() {
-	local f
-	for f in "${EROOT}"/var/lib/games/emacs/{snake,tetris}-scores; do
-		[ -e "${f}" ] || touch "${f}"
-	done
-	chown "${GAMES_USER_DED:-games}" "${EROOT}"/var/lib/games/emacs
-
-	elisp-site-regen
-	eselect emacs update ifunset
-
-	if use X; then
-		echo
-		elog "You need to install some fonts for Emacs."
-		elog "Installing media-fonts/font-adobe-{75,100}dpi on the X server's"
-		elog "machine would satisfy basic Emacs requirements under X11."
-		elog "See also http://www.gentoo.org/proj/en/lisp/emacs/xft.xml"
-		elog "for how to enable anti-aliased fonts."
-	fi
-
-	echo
-	elog "You can set the version to be started by /usr/bin/emacs through"
-	elog "the Emacs eselect module, which also redirects man and info pages."
-	elog "Therefore, several Emacs versions can be installed at the same time."
-	elog "\"man emacs.eselect\" for details."
-	echo
-	elog "If you upgrade from a previous major version of Emacs, then it is"
-	elog "strongly recommended that you use app-admin/emacs-updater to rebuild"
-	elog "all byte-compiled elisp files of the installed Emacs packages."
-}
-
-pkg_postrm() {
-	elisp-site-regen
-	eselect emacs update ifunset
-}