1 files changed, 51 insertions, 0 deletions
diff --git a/dev-cpp/cairomm/cairomm-1.10.0.ebuild b/dev-cpp/cairomm/cairomm-1.10.0.ebuild
new file mode 100644
index 000000000000..337a570e0045
--- /dev/null
+++ b/dev-cpp/cairomm/cairomm-1.10.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+GCONF_DEBUG="no"
+
+inherit eutils gnome2
+
+DESCRIPTION="C++ bindings for the Cairo vector graphics library"
+HOMEPAGE="http://cairographics.org/cairomm"
+SRC_URI="http://cairographics.org/releases/${P}.tar.gz"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="alpha amd64 arm hppa ia64 ppc ppc64 sh sparc x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
+IUSE="doc +svg"
+
+# FIXME: svg support is automagic
+RDEPEND="
+	>=x11-libs/cairo-1.10[svg?]
+	dev-libs/libsigc++:2
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? (
+		app-doc/doxygen
+		dev-libs/libxslt
+		media-gfx/graphviz )
+"
+
+src_prepare() {
+	# don't waste time building examples because they are marked as "noinst"
+	sed -i 's/^\(SUBDIRS =.*\)examples\(.*\)$/\1\2/' Makefile.in || die
+
+	# don't waste time building tests
+	# they require the boost Unit Testing framework, that's not in base boost
+	sed -i 's/^\(SUBDIRS =.*\)tests\(.*\)$/\1\2/' Makefile.in || die
+
+	# Fix docs installation, bug #443950
+	sed -i 's:libdocdir = \$(datarootdir)/doc/\$(book_name):libdocdir = \$(docdir):' docs/Makefile.in || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
+		--disable-tests \
+		$(use_enable doc documentation)
+}