1 files changed, 51 insertions, 0 deletions
diff --git a/dev-libs/libelf/libelf-0.8.13-r1.ebuild b/dev-libs/libelf/libelf-0.8.13-r1.ebuild
new file mode 100644
index 000000000000..d0540d96b9ca
--- /dev/null
+++ b/dev-libs/libelf/libelf-0.8.13-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="3"
+
+inherit eutils multilib autotools
+
+DESCRIPTION="A ELF object file access library"
+HOMEPAGE="http://www.mr511.de/software/"
+SRC_URI="http://www.mr511.de/software/${P}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="alpha amd64 arm hppa ~mips ppc ppc64 sparc x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="debug nls elibc_FreeBSD"
+
+RDEPEND="!dev-libs/elfutils"
+DEPEND="nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	epatch "${FILESDIR}/${P}-build.patch"
+	eautoreconf
+
+}
+
+src_configure() {
+	# prefix might want to play with this; unfortunately the stupid
+	# macro used to detect whether we're building ELF is so screwed up
+	# that trying to fix it is just a waste of time.
+	export mr_cv_target_elf=yes
+
+	econf \
+		$(use_enable nls) \
+		--enable-shared \
+		$(use_enable debug)
+}
+
+src_install() {
+	emake \
+		prefix="${ED}usr" \
+		libdir="${ED}usr/$(get_libdir)" \
+		install \
+		install-compat \
+		-j1 || die
+
+	dodoc ChangeLog README || die
+
+	# Stop libelf from stamping on the system nlist.h
+	use elibc_FreeBSD && rm "${ED}"/usr/include/nlist.h
+}