1 files changed, 86 insertions, 0 deletions
diff --git a/media-sound/umurmur/umurmur-0.2.11.ebuild b/media-sound/umurmur/umurmur-0.2.11.ebuild
new file mode 100644
index 0000000..6db89b7
--- /dev/null
+++ b/media-sound/umurmur/umurmur-0.2.11.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=3
+
+inherit eutils
+inherit autotools
+
+DESCRIPTION="Minimalistic Murmur (Mumble server)"
+HOMEPAGE="http://code.google.com/p/umurmur/"
+SRC_URI="https://github.com/fatbob313/${PN}/archive/ipv4.zip"
+
+LICENSE="BSD-3"
+SLOT="0"
+KEYWORDS="~x86 ~amd64"
+IUSE="polarssl"
+
+DEPEND="dev-libs/protobuf-c
+	dev-libs/libconfig
+	polarssl? ( >=net-libs/polarssl-1.1 )
+	!polarssl? ( dev-libs/openssl )"
+
+RDEPEND="${DEPEND}"
+
+pkg_setup() {
+	enewgroup umurmur || die
+	enewuser umurmur "" "" "" umurmur || die
+}
+
+src_unpack() {
+	unpack ${A}
+	if [[ ! -d ${S} ]]; then 
+		cd "${WORKDIR}"/${PN}* || die "failed to enter work directory" 
+		S="$(pwd)" 
+		einfo "Setting WORKDIR to ${S}" 
+	fi 
+}
+
+src_prepare() {
+	eautoreconf
+}
+
+src_configure() {
+	local myconf
+
+	# build uses polarssl by default, but instead, make it use openssl unless
+	# polarssl is desired.
+	use !polarssl && myconf="${myconf} --with-ssl=openssl"
+
+	econf ${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "install failed"
+
+	newinitd "${FILESDIR}/umurmurd.initd" umurmurd || die
+	newconfd "${FILESDIR}/umurmurd.confd" umurmurd || die
+
+	dodoc AUTHORS ChangeLog || die "dodoc failed"
+	newdoc README.md README || die "newdoc failed"
+
+	# Some permissions are adjusted as the config may contain a server
+	# password, and /etc/umurmur will typically contain the cert and the key
+	# used to sign it, which are read after priveleges are dropped.
+	insinto /etc
+	doins "${FILESDIR}/umurmur.conf" || die
+	fperms 0640 /etc/umurmur.conf || die
+
+	dodir /etc/umurmur || die
+	fperms 0750 /etc/umurmur || die
+	fowners root:umurmur /etc/umurmur || die
+}
+
+pkg_postinst() {
+	elog "A configuration file has been installed at /etc/umurmur.conf - you may "
+	elog "want to review it. See also http://code.google.com/p/umurmur/wiki/Configuring02x"
+
+	if use polarssl ; then
+		elog
+		elog "Because you have enabled PolarSSL support, umurmurd will use a"
+		elog "predefined test-certificate and key if none are configured, which"
+		elog "is insecure. See http://code.google.com/p/umurmur/wiki/Installing02x#Installing_uMurmur_with_PolarSSL_support"
+		elog "for more information on how to create your certificate and key"
+	fi
+}