1 files changed, 43 insertions, 0 deletions
diff --git a/mail-filter/imapfilter/imapfilter-2.6.16.ebuild b/mail-filter/imapfilter/imapfilter-2.6.16.ebuild
new file mode 100644
index 0000000..a260b1f
--- /dev/null
+++ b/mail-filter/imapfilter/imapfilter-2.6.16.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="An IMAP mail filtering utility"
+HOMEPAGE="https://github.com/lefcha/imapfilter"
+SRC_URI="https://github.com/lefcha/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 ~ppc ~x86"
+
+IUSE="libressl"
+
+RDEPEND="
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	dev-libs/libpcre
+	dev-lang/lua:*"
+DEPEND="${RDEPEND}"
+
+DOCS="AUTHORS NEWS README samples/*"
+
+src_prepare() {
+	default
+	sed -i -e "/^PREFIX/s:/usr/local:${EPREFIX}/usr:" \
+		-e "/^MANDIR/s:man:share/man:" \
+		-e "/^CFLAGS/s:CFLAGS =:CFLAGS +=:" \
+		-e "/^CFLAGS/s/-O//" \
+		src/Makefile || die
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)" LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	default
+	doman doc/imapfilter.1 doc/imapfilter_config.5
+}