blob: 478411fac0a6077fef358c618d9a9c862fb62346 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $
EAPI="5"
inherit eutils pax-utils autotools-multilib
DESCRIPTION="Streaming media framework"
HOMEPAGE="http://gstreamer.freedesktop.org/"
SRC_URI="http://${PN}.freedesktop.org/src/${PN}/${P}.tar.xz"
LICENSE="LGPL-2+"
SLOT="1.0"
KEYWORDS="~amd64"
IUSE="+introspection nls +orc test"
RDEPEND="
>=dev-libs/glib-2.32:2[${MULTILIB_USEDEP}]
introspection? ( >=dev-libs/gobject-introspection-1.31.1[${MULTILIB_USEDEP}] )
"
DEPEND="${RDEPEND}
app-arch/xz-utils
>=dev-util/gtk-doc-am-1.12
sys-devel/bison
sys-devel/flex
virtual/pkgconfig
nls? ( sys-devel/gettext[${MULTILIB_USEDEP}] )
"
# gtk-doc-am to install API docs
src_prepare() {
einfo "Patching configure for OOT build"
# Patch ugly configure sed hack (by means of ugly sed configure hack),
# to (hopefully) work when building OOT (untested on win32)
sed -e '/^sed \\$/imkdir -p win32/common' \
-e 's|^\([[:space:]]*\)\(config.h.in >win32/common/config.h-new\)|\1${srcdir}/\2|' \
-i configure{.ac,} || die configure OOT sed patch failed
epatch "${FILESDIR}"/${PN}-1.2.0-OOT-gtkdoc-install-hack.patch
AUTOTOOLS_AUTORECONF=yes
autotools-multilib_src_prepare
# remove ineffectual-but-harmless gtkdocize-installed gtk-doc.make
# (upstream uses their own customized version)
rm gtk-doc.make || die
}
src_configure() {
if [[ ${CHOST} == *-interix* ]] ; then
export ac_cv_lib_dl_dladdr=no
export ac_cv_func_poll=no
fi
if [[ ${CHOST} == powerpc-apple-darwin* ]] ; then
# GCC groks this, but then refers to an implementation (___multi3,
# ___udivti3) that don't exist (at least I can't find it), so force
# this one to be off, such that we use 2x64bit emulation code.
export gst_cv_uint128_t=no
fi
# Disable static archives, dependency tracking and examples
# to speed up build time
# Disable debug, as it only affects -g passing (debugging symbols), this must done through make.conf in gentoo
autotools-multilib_src_configure \
--disable-debug \
--disable-examples \
--disable-static \
--disable-valgrind \
--enable-check \
$(use_enable introspection) \
$(use_enable nls) \
$(use_enable test tests) \
--disable-maintainer-mode \
--disable-gtk-doc \
--with-package-name="GStreamer ebuild for Gentoo" \
--with-package-origin="http://packages.gentoo.org/package/media-libs/gstreamer"
}
src_install() {
AUTOTOOLS_PRUNE_LIBTOOL_FILES=modules
DOCS=(AUTHORS ChangeLog NEWS MAINTAINERS README RELEASE)
autotools-multilib_src_install
# Needed for orc-using gst plugins on hardened/PaX systems, bug #421579
use orc && pax-mark -m "${ED}usr/bin/gst-launch-${SLOT}" \
"${ED}usr/libexec/gstreamer-${SLOT}/gst-plugin-scanner"
}
|
GitWeb