dev-python/bottle/bottle-0.10.9.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/django-appconf/django-appconf-0.5.ebuild,v 1.1 2012/04/25 12:25:31 tampakrap Exp $

EAPI=4
PYTHON_DEPEND="2"
SUPPORT_PYTHON_ABIS=1
RESTRICT_PYTHON_ABIS="*-jython"

inherit distutils eutils

DESCRIPTION="A fast and simple micro-framework for small web-applications"
HOMEPAGE="http://pypi.python.org/pypi/bottle http://bottlepy.org/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE=""

PYTHON_MODNAME=bottle.py

RDEPEND="dev-python/simplejson"
DEPEND="${RDEPEND} dev-python/setuptools"

src_prepare() {
	distutils_src_prepare

	sed -e "/^sys.path.insert/d" -i test/{servertest.py,testall.py} || die
	epatch "${FILESDIR}"/bottle-0.10.9-python3tests.patch
}

src_test() {
	testing() {
		if [[ $(python_get_version --major) == 3 ]]; then
			# test/views are templates, data files, not copied over
			cp -a test/views/ build-${PYTHON_ABI}/lib/test/ || die "data file did not copy"
			pushd build-${PYTHON_ABI}/lib/ > /dev/null
			PYTHONPATH=. "$(PYTHON)" test/testall.py
			popd > /dev/null
		else
			# folder test in ${S} is Python2 compliant
			PYTHONPATH="build-${PYTHON_ABI}/lib/" "$(PYTHON)" test/testall.py
		fi
	}
	python_execute_function  testing
}