sys-process/nmon/nmon-14i.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-process/nmon/nmon-14i.ebuild,v 1.1 2014/03/19 20:58:31 polynomial-c Exp $

EAPI=5

inherit toolchain-funcs flag-o-matic

DESCRIPTION="Nigel's performance MONitor for CPU, memory, network, disks, etc..."
HOMEPAGE="http://nmon.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/lmon${PV}.c"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND="sys-libs/ncurses"
RDEPEND="${DEPEND}"

S=${WORKDIR}

src_unpack() {
	cp "${DISTDIR}"/lmon${PV}.c "${S}"/nmon.c || die
}

src_compile() {
	# if ncurses is built with separate tinfo libs, then...
	if has_version "sys-libs/ncurses[tinfo]" ; then
		if has_version "sys-libs/ncurses[unicode]" ; then
			CURSES_LIB="-lncursesw -ltinfow"
		else
			CURSES_LIB="-lncurses -ltinfo"
		fi
	else
		if has_version "sys-libs/ncurses[unicode]" ; then
			CURSES_LIB="-lncursesw"
		else
			CURSES_LIB="-lncurses"
		fi
	fi
	append-cppflags -DJFS -DGETUSER -DLARGEMEM -DPOWER
	emake CC="$(tc-getCC)" LDLIBS="${CURSES_LIB}" nmon
}

src_install() {
	dobin nmon
}